1.4 El Dinero y la Deuda P?blica.

1.4.1 Marco de Referencia

Los gobiernos manejan sus finanzas p?blicas seg?n programas y metas de corto y mediano plazo. Eso les ofrece  m?rgenes de maniobra para posponer o adelantar gastos e impuestos. Sin embargo, siempre quedan sujetos a una restricci?n presupuestal de largo plazo que consiste en que, tarde o temprano ellos deber?n cubrir las deudas que resulten de los d?ficit fiscales acumulados.

El modelo que vamos a usar en este cap?tulo tiene la misma estructura de los modelos que hemos venido presentando hasta ahora. Es decir, un sector de consumidores optimizadores y una tecnolog?a de producci?n que aplicada a los insumos explica la oferta de bienes. Sin embargo encontraremos dos diferencias. En primer lugar, haremos referencia expl?cita al tiempo. Es decir, reconoceremos que los instrumentos de deuda son veh?culos a trav?s de los cuales el p?blico y el gobierno  reacomodan sus ingresos y gastos en el tiempo. En segundo lugar, estaremos hablando de un mercado adicional, que es el mercado de deuda.

Hay que mencionar que el tema de la deuda p?blica desde la perspectiva Neocl?sica,  despert? un f?rtil debate al menos sobre tres aspectos que tienen relevancia en el dise?o de la pol?tica econ?mica. Desde el ?ngulo financiero, Samuelson demostr? en un art?culo publicado a mediados de los a?os cincuenta que  la existencia del gobierno puede no ser tan perjudicial como se propuso en la secci?n anterior, puesto que sus d?ficits permiten el surgimiento de instrumentos de ahorro  a los que el p?blico no tendr?a acceso de otra forma.

Desde la perspectiva presupuestal, Barro trajo a la mesa de discusi?n un tema que ya hab?a sido presentado por Ricardo dos siglos antes. Seg?n el, toda vez que el gobierno tiene que cobrar impuestos para pagar su deuda, el ahorro en t?tulos gubernamentales  terminar? por ser confiscado por la v?a tributaria. En ese sentido, el gobierno vuelve a parecer menos ben?fico de lo que Samuelson habr?a sugerido.

Finalmente, surgir? el tema del Dinero. En el fondo, el dinero no es otra cosa que un t?tulo de deuda emitido por el gobierno y que no paga intereses. Friedman y Cagan, entre otros, ven en este hecho la presencia de una clase especial de impuestos. Esta interpretaci?n dio lugar a la discusi?n sobre cu?l deber?a ser la cantidad m?s adecuada de dinero en la la econom?a as? como sobre el impuesto inflacionario ?ptimo.

En el cap?tulo siguiente seguiremos hablando de los mercados financieros donde incorporaremos un concepto adicional: el riesgo.

1.4.2 Comportamiento de las Familias

La funci?n de utilidad  que aparece a continuaci?n describe el caso de individuos que viven dos periodos. Ellos consumen las cantidades C1 y C2, respectivamente en cada uno de estos periodos. Se dice que su  funci?n de utilidad es separable, puesto que parace como si estas personas sumaran la utilidad del consumo en un periodo m?s la utilidad del consumo en el siguiente para determinar su bienestar total. El lector notar? que esta es una especificaci?n que se usa con frecuencia en la literatura sobre este tema.

>	restart: with(plots):

Warning, the name changecoords has been redefined

>	U:=(C1,C2)-> ln(C1)+mu*ln(C2):

El par?metro ofrece informaci?n sobre la forma en que la gente valora el consumo futuro en comparaci?n con el consumo presente. Si tomamos la tasa marginal de sustitucion entre ambos niveles de consumo, definida como , veremos que esta funci?n de utilidad es homot?tica, es decir que la pendiente de las curvas de indiferencia es igual a todos los niveles de utilidad en donde se conserve una relacion C1/C2=c, constante.

>	MRS:=-diff(U(C1,C2),C2)/diff(U(C1,C2),C1);

Adicionalmente, sabiendo que la elasticidad de sustituci?n de esta funci?n de utlidad est? dada por ,  vemos que para esta funci?n su valor es igual a la unidad.

>	C2:=C1/c: sigma:=diff(ln(MRS),c)*c; C1:='C1': C2:='C2': c:='c':

Supondremos que las personas nacen con una cierta dotaci?n de bienes de consumo, F. Sin embargo ellos por s? solos  carecen de una tecnolog?a adecuada para almacenarlos.  La parte que no consumen de dicha dotaci?n inicial la entregan al gobierno quien, a cambio de ello les da unos t?tulos de deuda. Por lo tanto, en este primer ejemplo estos t?tulos gubernamentales son equivalentes a certificados de dep?sito en una almacenadora.  

Esta almacenadora, a su vez, tiene una particularidad. Al final del periodo de almacenamiento puede regresar a los depositantes una cantidad igual, menor o superior a la que depositaron. Por ahora pensaremos en una tecnolog?a que exhibe rendimientos constantes. Es decir,  que al final de un periodo  los bienes ahorrados, F-C1 se transforman en  (1+r) (F-C1) bienes, los cuales se destinar?n  ya sea al consumo, C2, o a pagar impuestos, T, si los hubiera.

En este modelo el gobierno puede jugar dos papeles. Por un lado, mientras T=0, y mientras el gobierno regrese a los ahorradores el rendimiento ?ntegro de sus depositos, r(F-C1), estar? actuando s?lo como un intermediario financiero entre las familias y la almacenadora. Por otro lado, si el gobierno se apropia de parte de los rendimientos de los bienes almacenados para aplicarlos a sus gastos generales, entonces lo estaremos viendo en el mismo papel de recaudador y ejecutor del gasto p?blico que describimos en la cap?tulo anterior.

Por ahora concentr?monos en el primero de los roles, es decir, en el de intermediario financiero suponiendo que no se cobran impuestos.

1.4.3 Equilibrio General con mercados financieros completos

Para las familias, la aparici?n de un sistema financiero tiene un efecto positivo sobre su bienestar, toda vez que ahora pueden transferir recursos disponibles del periodo uno al periodo dos. En efecto, estar?n maximizando su funci?n de utilidad U, sujeto a la restricci?n , donde dicha restricci?n de hecho nos muestra la forma en que la dotaci?n inicial puede usarse para consumo presente o consumo futuro. Para compactar la notaci?n, referiremos  al valor presente de los flujos de gasto de los consumidores con la variable   . Finalmente, en esta secci?n supondremos que .

>	A:=(C1,C2)->C1+(C2+T)/(1+r);

Tal y como hemos venido haci?ndolo en los cap?tulos anteriores, las decisiones ?ptimas de consumo  en ambos periodos se obtienen resolviendo las condiciones de primer orden del Lagrangiano . Dejaremos al lector interesado delinear las condiciones de segundo orden.

>	Lambda:=(C1,C2,lambda)->U(C1,C2)+lambda*(F-A(C1,C2)); lc1:=(C1,C2,lambda)->diff(Lambda(C1,C2,lambda),C1): lc2:=(C1,C2,lambda)->diff(Lambda(C1,C2,lambda),C2): ll:=(C1,C2,lambda)->diff(Lambda(C1,C2,lambda),lambda):

>	solucion:=solve( {lc1(C1,C2,lambda)=0, lc2(C1,C2,lambda)=0, ll(C1,C2,lambda)=0}, {C1,C2,lambda}): assign(solucion);

>	c[1]:=unapply(C1,mu,r,F,T): c[2]:=unapply(C2,mu,r,F,T): lambda[o]:=unapply(lambda,mu,r,F,T):

Lo que resulta es muy interesante,

Si no existiera un veh?culo de almancenamiento, el individuo representativo se ver?a obligado a consumir toda su dotaci?n inicial en el primer periodo y 0 en el segundo.

Si tiene la oportunidad de ahorrar, consumir? solo una fracci?n en el primer periodo. Por cierto, dicha fracci?n depende de la valoraci?n relativa entre consumo presente y futuro, , proveniente de su funci?n de utilidad.

>	T:=0: factor(simplify(collect(c[1](mu,r,F,T),F)));

El consumo en el segundo periodo, , ser? igual al principal m?s el rendimiento del ahorro del primer periodo, .

>	factor(simplify(collect(c[2](mu,r,F,T),F)));

El equilibrio general en esta economia se obtiene cuando la oferta de recursos prestables (ahorro disponible), es igual a la demanda de dichos recursos prestables (capacidad de almacenamiento) a la tasa de inter?s de mercado.  En este caso supondremos que la capacidad de almacenamiento es ilimitada y que la tecnolog?a de almacenamiento rendimientos constantes, lo cual equivale a decir que la demanda de recursos prestables es perfectamente el?stica a la tasa de inter?s, r.

Gracias a este supuesto, la tasa de inter?s ser? igual a la tasa de rendimiento que ex?genamente fijamos para la tecnolog?a de almacenamiento. Por esta raz?n,  el ejercicio que resuelve el consumidor coincide trivialmente con el equilibrio general.
As? pues,  el hecho de que la tasa de rendimiento del ahorro sea constante sea cual sea la cantidad de bienes almacenados, se traduce en una frontera de posibilidades de producci?n en forma de una l?nea recta.
Visualmente, el nivel de utilidad que se tendr?a si los individuos no pudieran utilizar los mercados financieros  corresponde a la curva de indiferencia punteada, y el equilibrio inicial en E0. Al surgir el veh?culo para realizar las transferencias intertemporales, el equilibrio pasa al punto E1, en un nivel de bienestar claramente superior.  

>

T:='T': u:=U(c[1](mu,r,F,T),c[2](mu,r,F,T)): u[e]:=unapply(u,mu,r,F,T): mu:=0.7: r:=0.1: F:=1: T:=0: indiferencia:=implicitplot(U(c1,c2)=u[e](mu,r,F,T), c1=0.01..F, c2=0.01..F, labels=[`c1`,`c2`], color=black, title=`Solucion de equilibrio`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]): restriccion:=implicitplot(A(c1,c2)=F, c1=0.01..F, c2=0.01..F, color=blue): sin_mercado:=implicitplot(U(c1,c2)=U(F-(0.01),(1+r)*(0.01)), c1=0.01..F, c2=0.01..F, color=black, linestyle=2): equilibrio:=textplot([1.1*c[1](mu,r,F,T),1.1*c[2](mu,r,F,T),`E1`], font=[TIMES,ITALIC,10]): inicial:=textplot([F,0+0.1*F,`E0`], font=[TIMES,ITALIC,10]): display(indiferencia,restriccion,sin_mercado,equilibrio,inicial); mu:='mu': r:='r': F:='F': T:='T':

1.4.4 Equilibrio General con mercados financieros incompletos

Siguiendo la misma l?nea de argumentaci?n, es interesante ver qu? es lo que sucede si la capacidad de almacenamiento en nuestro ejemplo hipot?tico es limitada. En la pr?ctica, uno podr?a pensar en el caso en el que hay individuos que tienen acceso limitado a los mercados financieros, o bien que los mercados tienen algunos instrumentos de ahorro, pero no todos los que p?blico necesita.
En este caso, la frontera que describe las combinaciones factibles de consumo presente y consumo futuro, mostrar?a un quiebre en un punto arbitrario como  E2, donde ser? el equilibrio observado.
Cabe apuntar, que a pesar de tener mercados incompletos, el bienestar de la sociedad es superior al que se tendr?a sin instrumentos de ahorro en absoluto.

>

mu:=0.7: r:=0.1: F:=1: K:=0.25: T:=0: indiferencia[completo]:=implicitplot(U(c1,c2)=u[e](mu,r,F,T), c1=.50*c[1](mu,r,F,T)..1.50*c[2](mu,r,F,T), c2=.50*c[2](mu,r,F,T)..1.50*c[2](mu,r,F,T), labels=[`c1`,`c2`], color=black, title=`Solucion de equilibrio`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]): restriccion:=implicitplot(A(c1,c2)=F, c1=0..F, c2=0..F*(1+r), color=blue): capacidad:=inequal({c1>0,c2>0,c2<=(1+r)*K,A(c1,c2)<F}, c1=0..F, c2=0..F*(1+r), optionsexcluded=(color=white), optionsfeasible=(color=grey)): indiferencia[incompleto]:=implicitplot(U(c1,c2)=U(F-K,(1+r)*K), c1=.50*c[1](mu,r,F,T)..2*c[2](mu,r,F,T), c2=.50*c[2](mu,r,F,T)..2*c[2](mu,r,F,T), labels=[`c1`,`c2`], color=black, linestyle=2, thickness=2): equilibrio:=textplot([1.1*c[1](mu,r,F,T),1.1*c[2](mu,r,F,T),`E1`], font=[TIMES,ITALIC,10]): quiebre:=textplot([1.1*max(F-K,c[1](mu,r,F,T)), 1.1*min((1+r)*K,c[2](mu,r,F,T)),`E2`], font=[TIMES,ITALIC,10]): display(indiferencia[completo], indiferencia[incompleto], restriccion, capacidad, equilibrio, quiebre); K:='K': mu:='mu': r:='r': F:='F': T:='T':

Los expresiones de Maple 8 que se presentan enseguida, corresponden a los niveles de equilibrio del consumo presente, , y futuro, . Se declaran aqu? a fin de que queden cargadas en la memoria del computador toda vez que se utilizar?n m?s adelante en la secci?n de preguntas del cap?tulo.

>	cr1:=max(F-K,c[1](mu,r,F,T)): cr2:=min((1+r)*K,c[2](mu,r,F,T)): c[r1]:=unapply(cr1,mu,r,F,T,K): c[r2]:=unapply(cr2,mu,r,F,T,K):

1.4.5 Las finanzas p?blicas, el dinero y la Equivalencia Ricardiana

En los p?rrafos anteriores hemos visto al gobierno como un simple intermediario entre el almac?n y los ahorradores .

Aqu?  vamos a modificar un poco esta historia. En lugar de un almac?n en el que la gente deposita sus recursos, supondremos que el gobierno financia su gasto del primer periodo con bonos que coloca entre el p?blico ahorrador. Supondremos que ese gasto no  se aplica a actividades productivas que generen un rendimiento que le permitan a este ?ltimo cubrir principal e intereses al vencimiento . De hecho,  supondremos  que el gobierno los aplica a gastos generales.

Sabemos, adem?s, que si el gobierno emite deuda y despu?s tiene que pagarla,  tendr? que cobrar impuestos por un monto equivalente a los pagos que debe hacer al p?blico en el segundo periodo.  

La soluci?n del consumidor en el caso donde que el gobierno toma deuda, paga la tasa de rendimiento , y simult?neamente cobra una cantidad de impuestos  de impuestos se ilustra en la gr?fica siguiente.

>

mu:=0.7: r:=0.1: F:=1: T:='T': for j from 0 by 2 while j < 5 do  T:=j/10: indiferencia[j]:=implicitplot(U(c1,c2)=u[e](mu,r,F,T), c1=.50*c[1](mu,r,F,T)..1.50*c[2](mu,r,F,T), c2=.50*c[2](mu,r,F,T)..1.50*c[2](mu,r,F,T), labels=[`c1`,`c2`], color=black, linestyle=j/2, thickness=2-j/2, title=`Respuesta del consumidor`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]): restriccion[j]:=implicitplot(A(c1,c2)=F, c1=.50*c[1](mu,r,F,T)..1.50*c[1](mu,r,F,T), c2=.50*c[2](mu,r,F,T)..1.50*c[2](mu,r,F,T), linestyle=j/2, thickness=2-j/2, color=blue): equilibrio[j]:=textplot([1.1*c[1](mu,r,F,T),1.1*c[2](mu,r,F,T),cat(`E`,j/2)], font=[TIMES,ITALIC,10]): end do: display([seq(indiferencia[j*2],j=0..2), seq(restriccion[j*2],j=0..2), seq(equilibrio[j*2],j=0..2)]); T:='T': mu:='mu': r:='r': F:='F':

La pendiente de la l?nea de restricci?n presupuestal est? dada por , mientras que la posici?n de dicha restricci?n depende del nivel de impuestos .   La secuencia de puntos corresponde a mayores niveles de impuestos a medida que i aumenta.

A simple vista, una estrategia de financiamiento del d?ficit consistente en la emisi?n en el primer periodo de bonos que pagan una tasa positiva y la correspondiente pol?tica de recaudaci?n consistente en cobrar una cantidad  en el segundo periodo, se antoja como uan soluci?n razonable, pero sobre todo factible para atender el problema del d?ficit fiscal.

Desafortunadamente, esta combinaci?n de impuestos y deuda   impuestos  plantea un problema no muy obvio. En efecto,  una caracter?stica que podemos esperar de la respuesta de los consumidores, es que mientras m?s elevado sea el impuesto , mayor es el ahorro del p?blico en el primer periodo (menor es ), ya que los individuos buscan minimizar el impacto de los impuestos sobre su bienestar. Lo que no se ve en la gr?fica pero que se demostrar? m?s adelante, es que cada uno de los puntos de tangencia que aparecen en ella corresponden a un nivel de impuestos, T, inferior al necesario para cubrir plenamente el principal e intereses de la deuda a la tasa de rendimiento , es decir, , para toda T  . Esto conduce a una inc?moda conclusi?n: para cualquier nivel de deuda p?blica, no existe un impuesto fijo que permita pagar la tasa , y al mismo tiempo generar los ingresos necesarios para pagar principal e intereses.

Otra  manera de ver de lo que estamos hablando consiste en calcular la tasa de inter?s que satisface la restricci?n presupuestal del gobierno. El resultado que aparece enseguida establece que dicha tasa de inter?s tendr?a que ser negativa  para cualquier nivel de impuestos .

>	solve((1+r)*(F-c[1](mu,r,F,T))=T,{r});

Desde la perspectiva de los impuestos, el punto en el que se satisfacer?a la restricci?n del presupuesto gubernamental para una tasa de inter?s , se tiene donde el nivel de los impuestos fuera, en valor presente, igual a la riqueza total de las familias, lo cual es ciertamente un caso extremo.

>	solve((1+r)*(F-c[1](mu,r,F,T))=T,{T});

Esta situaci?n tiene tres posibles soluciones, de cuyo an?lisis se desprende que tanto el dise?o del r?gimen de recaudaci?n como de los propios instrumentos financieros, juegan un papel determinante. As? pues,  :

O el equilibrio se da en una modalidad similar a la de los mercados incompletos explorados arriba, es decir, donde el gobierno emite una cierta cantidad de deuda a la tasa predeterminada r, y el p?blico toma dicha deuda aunque ello signifique un menor ahorro que el deseado.

O el gobierno invierte parte del gasto en actividades productivas que le generen un rendimiento suficiente para cerrar la brecha presupuestal, lo cual hemos supuesto que no sucede.

O el gobierno no recauda  por la v?a de un impuesto fijo, T, sino mediante un impuesto al ahorro, . Es decir, pagando un rendimiento probablemente negativo a los ahorradores, sobre la deuda emitida.  

Es esta tercera opci?n la que da lugar al concepto de dinero, el cual  es precisamente un instrumento de deuda, emitido por el gobierno, que paga un rendimiento negativo en t?rminos reales.

La gr?fica, por ejemplo, muestra que el p?blico est? dispuesto a ahorrar, a?n si esto implica aceptar tasas de rendimiento negativas, , en t?rminos reales. De hecho, se ilustra lo que sucede cuando toma valores en el intervalo de -0.6 a -0.2.  La raz?n por la cual la gente acepta esta situaci?n es que la utilidad marginal del consumo en el periodo 2 es arbitrariamente grande cuando C2 es cercano a cero. Por lo tanto, el p?blico est? dispuesto a sacrificar rendimiento si a cambio puede transferir parte de su riqueza presente al futuro. Esto abre una oportunidad recaudatoria muy importante para el gobierno.

>

mu:=0.7: F:=1: T:=0: for j from 0 by 1 while j < 3 do  r:=-j/5: indiferencia[j]:=implicitplot(U(c1,c2)=u[e](mu,r,F,T), c1=.50*c[1](mu,r,F,T)..1.5*c[1](mu,r,F,T), c2=.50*c[2](mu,r,F,T)..1.5*c[2](mu,r,F,T), labels=[`c1`,`c2`], color=black, linestyle=j, thickness=3-j, title=`Equilibrio con Impuesto Inflacionario`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]): restriccion[j]:=implicitplot(A(c1,c2)=F, c1=.50*c[1](mu,r,F,T)..2.50*c[1](mu,r,F,T), c2=.50*c[2](mu,r,F,T)..2.50*c[2](mu,r,F,T), linestyle=j, thickness=2-j, color=blue): equilibrio[j]:=textplot([1.01*c[1](mu,r,F,T),1.05*c[2](mu,r,F,T),cat(`E`,j)], font=[TIMES,ITALIC,8]): end do: display([seq(indiferencia[j],j=0..2), seq(restriccion[j],j=0..2), seq(equilibrio[j],j=0..2)]); mu:='mu': r:='r': F:='F': T:='T':

As? pues, el gobierno emite dinero en un cierto periodo, y en el periodo siguiente el ahorrador recibe el principal menos el rendimiento (negativo) del dinero, es decir, la inflaci?n. Es por eso que este impuesto se conoce como impuesto inflacionario.

La base de dicho impuesto es precisamente el ahorro del p?blico, , donde hemos sustituido la tasa de rendimiento, r, por .

Si vemos nuevamente la ?ltima gr?fica notaremos que los puntos de tangencia, , se encuentran exactamente arriba el uno del otro. Eso quiere decir que para  la funci?n de utilidad con que hemos venido trabajando, el gobierno se encuentra con la favorable circunstancia de que la oferta de fondos prestables es inel?stica a variaciones en la tasa de rendimiento (inflaci?n). En otras palabras, la base del impuesto es constante.

>	base:=F-c[1](mu,-pi,F,T): b:=unapply(base,mu,r,pi,F,T): plot(b(0.7,.20,pi,1,0), pi=0.01..0.90, axes=boxed, title=`Base del Impuesto Inflacionario`, color=black, labels=[`-p`,``], titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], font=[TIMES,BOLDITALIC,9], labelfont=[SYMBOL,9]);

Esto significa que en una econom?a como esta,  el gobierno siempre podr? fijar el nivel de su d?ficit  y financiarlo  mediante alguna combinaci?n de emisi?n de dinero e  inflaci?n. Tal capacidad de recaudaci?n ,  se ilustra en la gr?fica siguiente. Hay que hacer notal que los resultados est?n dados como proporci?n de la riqueza, la cual aqu? se asume igual a la unidad .

>

inf:=pi*(F-c[1](mu,-pi,F,T)): inftax:=unapply(inf,mu,r,pi,F,T): plot(inftax(0.7,.20,pi,1,0), pi=0.01..0.90, axes=boxed, title=`Recaudacion por Impuesto Inflacionario`, color=black, labels=[`tasa de inflacion`,`% de la riqueza`], labeldirections=[HORIZONTAL,VERTICAL], titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], font=[TIMES,BOLDITALIC,9], labelfont=[TIMES,ITALIC,9]);

Este resultado sustenta varias conclusiones importantes:

No necesitamos de una tecnolog?a de almacenamiento rentable para permitir que los individuos ahorren.

La emisi?n de dinero es una respuesta adecuada a la necesidad de financiamiento intertemporal de las finanzas p?blicas y adem?s permite a la gente mejorar la distribuci?n intertemporal del consumo.

Mientras no existan veh?culos m?s eficientes para ahorrar, se justifica la intervenci?n del gobierno en la econom?a. Esta intervenci?n de hecho resuelve una falla del mercado, la cual hemos denominado mercados incompletos.

El equilibrio del mercado, sin racionamiento y sin una tecnolog?a rentable de almacenamiento, s?lo puede darse a tasas de rendimiento negativas, es decir, con inflaci?n.

Ahora bien, en cuanto a la Equivalencia Ricardiana, debe precisarse que si bien es cierto que la deuda presente debe pagarse en el futuro, tambi?n lo es que el gobierno cuenta con veh?culos, como el dinero, que le permiten no pagar la totalidad de dicha deuda y a?n estar en condiciones de colocarla voluntariamente entre el p?blico ahorrador. En consecuencia, si pensamos en valores gubernamentales que compiten con t?tulos que ofrecen un rendimiento real positivo, tendremos que aceptar que los d?ficits fiscales no son sostenibles. Por el contrario, mientras los mercados sean tales que el p?blico acepte valores que paguen tasas reales negativas, tales d?ficits podr?n existir.

1.4.6 Usando el modelo

Pregunta 1.  Seg?n el modelo, ?qu? tan grande podr?a ser el gasto p?blico si tomamos como criterio al bienestar social?

La introducci?n del dinero, seg?n vimos, genera un excedente en los ahorradores por el s?lo hecho de facilitar la realizaci?n de transferencias intertemporales. Dicho excedente puede ser usado por el gobierno, de manera que el efecto neto sobre el bienestar la poblaci?n, comparado con la  situaci?n en la que no hay mercados financieros, sea positivo.

Usaremos a la primera gr?fica  s?lo como referencia. Esta muestra el tama?o del excedente, expresado en las unidades que correspondan a la funci?n de utilidad, que resulta de ir aumentando el balance de la deuda disponible al p?blico.

La superficie se comporta como (el antilogaritmo del) cociente de la utilidad con mercados financieros entre la utilidad sin mercados, para distintos valores de K; .  En este ejemplo se supone que y que F=1.

>	ur:=U(c[r1](mu,r,F,T,K),c[r2](mu,r,F,T,K)): u[r]:=unapply(ur,mu,r,F,T,K):

>

ex:=limit(exp(u[r](mu,r,F,T,K))- exp(U(F-a,a*(1+r))),a=0,right): excedente:=unapply(ex,mu,r,F,T,K): plot3d(excedente(0.7,r,1,0,K),K=0.01..0.8,r=-0.50..0.50, axes=boxed, orientation=[-140,60], title=`Excedente`, style=patchcontour, shading=zhue, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]);

La segunda gr?fica traduce este resultado en unidades f?sicas del bien que consumen los individuos. De esta manera,  podemos hablar de la relaci?n entre gasto y riqueza. Esta cantidad resulta de clcular cu?l ser?a la riqueza inicial, f[o] con mercados completos, que permite alcanzar un nivel de utilidad equivalente al nivel de utilidad que las familias experimentar?an con mercados incompletos pero con una riqueza inicial F. La diferencia  F-f[o], es el tama?o aceptable del sector p?blico.

>	x:='x': F1:='F1': x:=solve(exp(u[e](mu,r,F1,T))-exp(U(F-0.1,0.1*(1+r))),{F1}): assign(x): f[o]:=unapply(F1,mu,r,F,T):

>	F:=1: T:=0: plot(F-f[o](mu,0.10,F,T),mu=0.1..0.9, axes=boxed, labels=[`m`,``], color=black, title=`Recaudacion a Riqueza`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[SYMBOL,9]); F:='F': T:='T':

En este ejemplo, dado que la utilidad marginal en niveles de muy bajos de C es muy alta, el tama?o aceptable de gobierno puede llegar a cerca del 35% para valores de superiores a 0.9. Cabe apuntar que este resultado depender? de la especificaci?n y par?metros de la funci?n de utilidad.
El lector interesado podr? comprobar que estos valores son muy sensibles a la forma de la funci?n de utilidad en niveles de consumo bajos.

Pregunta 2. ?C?mo se determinar?a la tasa de inter?s  si la tecnolog?a de almacenamiento tiene rendimientos decrecientes?

Un supuesto que manejamos en la primera parte del cap?tulo, en buena medida con el fin simplificar la construcci?n del modelo y el an?lisis de los resultados, fue el de rendimientos constantes en la tecnolog?a de almacenamiento. Otra manera de interpretar este supuesto es que la demanda de fondos prestables es perfectamente el?stica a un cierto nivel de tasas, r.

Al relajar este supuesto tendremos que determinar simult?neamente tanto el nivel de ahorro como la tasa de rendimiento de equilibrio en el mercado.
Una manera de  modelar rendimientos decrecientes en el almacenamiento, o bien una demanda de fondos prestables con pendiente negativa, ser?a suponer que , donde  es el rendimiento del lado de la demanda. Si as? lo quiere el lector, podr?a suponer que los demandantes de fondos son  empresas que utilizan los recursos ahorrados como insumos en una funci?n producci?n, de forma   puede interpretarse como la productividad marginal del insumo que se pidi? prestado (capital) y como la renta de este insumo.

>	C1:='C1': F:='F': solucion:=solve(rd=alpha-beta*(F-C1),{C1}): assign(solucion):

>

solucion:=solve(c[1](mu,rd,F,0)=C1,{rd}): assign(solucion): r[d]:=unapply(rd,mu,alpha,beta,F): cs1:=c[1](mu,r[d](mu,alpha,beta,F),F,0): cs2:=c[2](mu,r[d](mu,alpha,beta,F),F,0): c[s1]:=unapply(cs1,mu,alpha,beta,F): c[s2]:=unapply(cs2,mu,alpha,beta,F): us:=U(c[s1](mu,alpha,beta,F),c[s2](mu,alpha,beta,F)): u[s]:=unapply(us,mu,alpha,beta,F):

Como lo hemos venido haciendo hasta ahora, el equilibrio general se alcanzar? donde la tasa marginal de sustituci?n entre consumo presente y futuro sea igual a la tasa marginal de transformacion correspondiente, seg?n aparece en la gr?fica siguiente.

>

mu:=0.7: alpha:=0.20: beta:=0.40: F:=1: indiferencia:=implicitplot(U(c1,c2)=u[s](mu,alpha,beta,F), c1=.50*c[s1](mu,alpha,beta,F)..1.50*c[s1](mu,alpha,beta,F), c2=.50*c[s2](mu,alpha,beta,F)..1.50*c[s2](mu,alpha,beta,F), labels=[`c1`,`c2`], color=black, title=`Solucion de equilibrio`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]): restriccion:=implicitplot( (F-c1)*(1+alpha-beta*(F-c1))= c2, c1=.05*c[s1](mu,alpha,beta,F)..2.50*c[s1](mu,alpha,beta,F), c2=.05*c[s2](mu,alpha,beta,F)..2.50*c[s2](mu,alpha,beta,F), color=blue): display(indiferencia,restriccion); alpha:='alpha': beta:='beta': mu:='mu': F:='F':

Obviamente, el nivel de la tasa de inter?s depender? del tama?o de la econom?a que nos ocupe ,F , de la estructura de preferencias, , y de la tecnolog?a, .

>	collect(r[d](mu,alpha,beta,F),mu);

En seguida se presenta la gr?fica de la relaci?n entre y r en el equilibrio general, para distintos valores de .

>

alpha:=0.3: for j from 5 by 1 while j < 8 do  beta:=j/10: grafica[j]:=plot([mu,r[d](mu,alpha,beta,1),mu=0.01..0.7], linestyle=j-4, thickness=8-j, axes=boxed, title=`Tasa de interes de equilibrio`, color=black, labels=[`m`,``], titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], font=[TIMES,BOLDITALIC,9], labelfont=[SYMBOL,9]); nota[j]:=textplot([0.6, 0.5*(r[d](0.6,alpha,beta,1))+ 0.5*(r[d](0.7,alpha,beta,1)), b=evalf(beta,1)], font=[SYMBOL,10]): end do: alpha:='alpha': display(grafica[5],grafica[6],grafica[7], nota[5],nota[6],nota[7]);

Pregunta 3.  ?Cu?l es la tasa ?ptima de inflaci?n desde el punto de vista recaudatorio?

En las secciones anteriores vimos que dada la funci?n de utilidad que especificamos, la base del impuesto inflacionario era constante. En consecuencia, la respuesta a la pregunta es que mientras , la gente aceptar? al dinero como veh?culo para hacer transferencias intertemporales.

En ese contexto, el gobierno tendr?a los incentivos para recurrir a la hiperinflaci?n como veh?culo recaudatorio.

Sin embargo, es interesante ver lo que sucede cuando suponemos que la elasticidad de sustituci?n entre consumo presente y futuro, a niveles bajos de ahorro, no es igual a uno..

Tomemos, por ejemplo, a una funci?n tipo CES (Elasticidad de Substituci?n Constante), , y volvamos a resolver el equilibrio general, ahora varios valores de la elasticidad de sustituci?n .  El lector podr? ver en la gr?fica siguiente c?mo se modifica la forma de las curvas de indiferencia al cambiar el valor de .  En este caso se ilustra lo que sucede con una elasticidad de sustituci?n de  0.5, es decir, .

>

restart: with(plots): U:=(C1,C2)-> (alpha*C1^(-rho)+(1-alpha)*C2^(-rho))^(-1/rho): A:=(C1,C2)->C1+ C2/(1+r): Lambda:=(C1,C2,lambda)->U(C1,C2)+lambda*(F-A(C1,C2)): lc1:=(C1,C2,lambda)->diff(Lambda(C1,C2,lambda),C1): lc2:=(C1,C2,lambda)->diff(Lambda(C1,C2,lambda),C2): ll:=(C1,C2,lambda)->diff(Lambda(C1,C2,lambda),lambda): solucion:=solve( {lc1(C1,C2,lambda)=0, lc2(C1,C2,lambda)=0, ll(C1,C2,lambda)=0}, {C1,C2,lambda}): assign(solucion); c[1]:=unapply(C1,alpha,rho,r,F): c[2]:=unapply(C2,alpha,rho,r,F): lambda[o]:=unapply(lambda,alpha,rho,r,F): u:=U(c[1](alpha,rho,r,F),c[2](alpha,rho,r,F)): u[e]:=unapply(u,alpha,rho,r,F): alpha:=0.7: rho:=1: r:=-0.2: F:=1: indiferencia:=implicitplot(U(c1,c2)=u[e](alpha,rho,r,F), c1=0..1, c2=0..1, labels=[`c1`,`c2`], color=black, title=`Solucion de equilibrio`, titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], labelfont=[TIMES,BOLDITALIC,9]): restriccion:=implicitplot(A(c1,c2)=F, c1=0..1, c2=0..1, color=blue): equilibrio:=textplot([1.1*evalf(c[1](alpha,rho,r,F)), 1.1*evalf(c[2](alpha,rho,r,F)),`E1`], font=[TIMES,ITALIC,10]): display(indiferencia,restriccion,equilibrio); alpha:='alpha': rho:='rho': r:='r': F:='F':

Warning, the name changecoords has been redefined

A continuaci?n simplemente replicamos el ejercicio del impuesto inflacionario para varios escenarios de elasticidad de sustituci?n, ,

>	inf:=pi*(F-c[1](alpha,rho,-pi,F)): inftax:=unapply(inf,alpha,rho,r,pi,F):

>

for j from -2 by 1 while j < 3 do  rho:=(j/5): grafica[j]:=plot(inftax(0.7,rho,.20,pi,1), pi=0.01..0.90, axes=boxed, title=`Recaudacion por Impuesto Inflacionario`, color=black, labels=[`-p`,``], titlefont=[TIMES,BOLDITALIC,12], axesfont=[TIMES,ITALIC,8], font=[TIMES,BOLDITALIC,9], labelfont=[SYMBOL,9]): nota[j]:=textplot([0.5,1.2*evalf(inftax(0.7,rho,.20,0.5,1)),s=evalf(1/(1+rho),2)], font=[SYMBOL,10]): end do: display(grafica[1],grafica[2],grafica[3], nota[1],nota[2],nota[3]); display([seq(grafica[j],j=-2..2), seq(nota[j],j=-2..2)]);

De esta gr?fica se desprende que cuando  la elasticidad de sustituci?n entre consumo presente y futuro es mayor a la unidad, ,  habr? una tasa de inflaci?n ?ptima, por encima (o por debajo) de la cual el gobierno recaudar?a menos.
Tambi?n se desprende de esta gr?fica, que la capacidad de recaudaci?n del gobierno es mucho menor que la que se ten?a cuando la elasticidad de sustituci?n era igual a uno.

Finalmente, vale la pena hacer una precisi?n sobre lo que significa . Esta es la tasa de rendimiento del dinero. En consecuencia, la tasa de inflaci?n debe ser definida como . As?, por ejemplo, en el caso donde la elasticidad de sustituci?n es de 1.7, el rendimiento negativo ?ptimo es de aproximadamente 0.6, lo que implicar?a una tasa de inflaci?n de 150%.

Lecturas Recomendadas

Barro, Robert. On the Determination of the Public Debt. Journal of Political Economy, vol 87, 1979

Bullard, James. Samuelson?s Model of Money with n-period lifetimes. Review of the FRB of St. Louis, 1992

Cagan, Phillip. Determinants and Effects of changes in the stock of Money: 1875-1960. NBER, New York, 1965

Samuelson, Paul. An exact consumption loan model of interest with or without the contrivance of money. Journal of Political Economy, vol 66, 1958