Ramachandran Map
Godfrey Beddard, School of Chemistry, University of Leeds, LS2 3JT UK.
The Ramachandram map is a plot of the phi vs psi torsion angles in a protein and is formed by adding a point at (f, y) for each amino acid residue.The angles range from +-180o.
A torsion angle is defined between two planes, for example as the angle between the two pages of an open book, and in a protein these angles are defined as shown in the figure. The backbone O=C-N(H)Ca and the CaC(=O)NH atoms are each in a plane (shown shaded) and the angle y is that between the planes containing the Ca and N atoms and that containing the C(=O) and N(H) atoms, and f bewtween (O=)CN and CaC(=O) as shown.
Although Ca has only single bonds which are therefore free to rotate, not all psi and phi torsion angles are observed because van der Waals interactions between non-bonded atoms in the backbone, and with atoms in the amino acid residues, R, make large ranges of angles too high in energy to be observed in most proteins. For example, if the oxygen atoms are ingored, and the bond (N-Ca) (angle f ) is rotated the two carbon atoms eventually reach a cis conformation rather than the trans shown above. They are now relatively close to one another and because of the mutual repulsion of their electrons this conformation may not be allowed and is sterically forbidden.
The main secondary structures of proteins are the a-helix and b-sheet. Alpha helices are found in the region bouded approximately by (f) phi = -60 +/- 10 , (y) psi = -45 +/- 10 , and b-sheets in the region phi = -45 to -150, psi = 100 to 180.
Ramachandran maps (also called plots) are described in most textbook dealing with protiens, see Branden & Tooze, 'Introduction to Protein Science', publ Garland Publishing 1991, or Finkelstein and Ptitsyn, 'Protein Physics', publ Academic Press, 2002. See Davis et al. Proteins vol, 50 p 437, 2003 for a more sophisticated method of calculating forbidden regions. Calculating torsion angles and general properties of vectors are described in Beddard, 'Applying Maths in the Chemical and Biosciences, an example based approach', publ OUP, 2009.
To use this programmme
(1) Download some data from the RCSB Protein data bank http://www.rcsb.org/pdb/home/home.do
(2) The input is all of pdb file just as downloaded
(3) Put the data in the same folder as this document and finally add the .pdb name to the list as shown below. Some examples are shown
The output is
(1) Torsion angles. This option can be disabled at the printf statements which are placed just before plotting.
(2) Ramachandran graphs produced are
(a) all residues, (b) glycines only , (c) prolines only and (d) pre-prolines only
Superimposed on the maps are grey lines to indicate the (approximate) sterically allowed areas.
| > |
restart: with(LinearAlgebra): with(plots): with(StringTools): |
| > |
#####################################################################
# some pdb data set names
dataname:= `1FBB.pdb`: # bacteriorhodopsin, largely alpha helix
#dataname:= `1jb0.pdb`: # photosystem 1, huge data set
#dataname:= `1THB.pdb`: # haem largely alpha helix
#dataname:= `107L.pdb`: # myoglobin, largely alpha-helix
#dataname:= `1RUZ.pdb`: # hemoggutinin 2028 residues
#dataname:= `I27.pdb`: # I27, small protein
#dataname:= `1qjp.pdb`: # beta-barrel, E-coli outer membrane protein, 170 residues
#dataname:= `1crn.pdb`: # crambin
#dataname:= `1alc.pdb`: # alpha lactalbumin, 212 residues
#dataname:= `1e1q.pdb`: # Bovine ATPase; huge data set, 3225 residues
|
| > |
#####################################################################
ramachandran:= proc(dataname)
local TorsionAngle,angle_psi,angle_phi,aline,n_atoms,n,st,MAT,j,k,i,len,m,val_phi,jend,resd,val_psi,res_name,ss,res_A,phi_A,psi_A,ss_A,p1,p2,p3,p4,L1:
global indx,Solid_Lines,lines:
# proc TorsionAngle ################################################
# calculate torsion angle given atom coordinates
TorsionAngle:= proc(atom1,atom2,atom3,atom4)
local m,n,A,B,C,cos_angle,angle:
A:=atom2-atom1; B:=atom3-atom2: C:=atom4-atom3:
m:= A &x B:
n:= B &x C:
cos_angle:=(m . n )/(sqrt(n.n)*sqrt(m.m));
angle:= sign(A.n) * evalf( arccos(cos_angle)*180.0/Pi );
end proc:
# proc angle_psi ################################################
# search for atoms N-CA-C-N coordinates starting at position m in pdb list
angle_psi:= proc( m )
global indx:
local n,j,i,N1,C,CA,N2,psi,n_atom,c_atom:
n_atom:="N":
c_atom:="C":
j:= 0:
while MAT[m+j,3] <> n_atom do j:=j+1; end do;
n:= m + j;
N1:= < MAT[n,7] | MAT[n,8] | MAT[n,9] >;
CA:= < MAT[n+1,7]| MAT[n+1,8]| MAT[n+1,9]>;
C:= < MAT[n+2,7]| MAT[n+2,8]| MAT[n+2,9]>;
i:=1:
while MAT[n+i,3] <> n_atom do i:= i + 1; end do:
if MAT[n+i,3] = n_atom then
N2:= < MAT[n+i,7]| MAT[n+i,8]| MAT[n+i,9]>; end if;
indx:= n + i:
TorsionAngle(N1,CA,C,N2);# angle psi
end proc: |
| > |
# proc angle_phi ################################################
# search for atoms C-N-CA-C starting at position m in pdb list
angle_phi:= proc( m )
global indx:
local n,j,i,C1,N,CA,C2,phi,n_atom,c_atom:
n_atom:="N":
c_atom:="C":
j:= 0:
while MAT[m+j,3] <> c_atom do j:= j + 1; end do;
n:= m + j;
C1:= < MAT[n,7] | MAT[n,8] | MAT[n,9]> ;
i:= 1:
while MAT[n+i,3] <> n_atom do i:= i + 1; end do:
N:= < MAT[n+i,7] | MAT[n+i,8] | MAT[n+i,9] >;
CA:= < MAT[n+i+1,7]| MAT[n+i+1,8]| MAT[n+i+1,9]>;
C2:= < MAT[n+i+2,7]| MAT[n+i+2,8]| MAT[n+i+2,9]>;
indx:= n + i + 2:
TorsionAngle(C1,N,CA,C2); # angle phi
end proc:
# proc Solid_lines ################################################
############ solid lines for conventionally folded structures ############
Solid_Lines:= proc() # approximate angles
local xa,ya,sa:
lines:=[ ]:
xa:=[-176, -57, -40, -40, -108, -108, -40, -40, -175, -175, -159, -95, -95, -176, -176]:
ya:=[180, 180, 163, 98, 98, 36, -30, -66, -66, -40, -58, -58, -21, 60, 180]:
sa:=seq([xa[i],ya[i]],i=1..nops(xa)):
lines:=[op(lines),plot([sa],color=grey)];
xa:=[62, 62, 41, 41, 62];
ya:=[125, 13, 36, 102, 125];
sa:=seq([xa[i],ya[i]],i=1..nops(xa)):
lines:=[op(lines),plot([sa],color=grey)];
xa:=[-177, -63, -63, -177, -177]:
ya:=[-168, -168, -179, -179, -168]:
sa:=seq([xa[i],ya[i]],i=1..nops(xa)):
lines:=[ op(lines), plot([sa],color=grey) ];
end proc:
################################################
|
| > |
# read all of pdb look for ATOM
aline:= readline(dataname): # work out size of data
n_atoms:=0: n:= 1: st:=0:
while aline <> 0 do
aline:=readline(dataname):
if aline[1..4] = "ATOM" then
n_atoms:= n_atoms + 1;
if st = 0 then st:= n + 1: end if
end if;
n:= n + 1;
end do:
printf("%s %a %s %a %s %a \n","Atom coords start at line",st ," and there are ",n_atoms, "atoms. pdb ends at line", n-1);
MAT:= Matrix(n_atoms,12):
################################################
# now read data into matrix MAT
# reading is done explicitly because there are not always gaps between different entries
# in the line of data i.e. CD1AILE can occur rather than CD1 ILE
j:= 1:
res_A:= 0:
for k from 1 to n - 1 do
aline:= readline(dataname):
if k >= st and aline[1..4] = "ATOM" then
m:=sscanf(aline, "%27c %8f %8f %8f %4f %6f %s");
MAT[j,1]:= m[1][1..4]; # atom # 1
MAT[j,2]:= convert(DeleteSpace(m[1][5..11]),decimal,10); # atom number # 2
MAT[j,3]:= DeleteSpace(m[1][12..16]); # atom label # 3
MAT[j,4]:= DeleteSpace(m[1][17..20]); # residue name # 4
MAT[j,5]:= DeleteSpace(m[1][21..23]); # chain A , B etc. # 5
# check if some residues are labelled 49A for example
if m[1][27]<> " " then res_A:= res_A + 1: end if:
MAT[j,6]:= convert(DeleteSpace(m[1][24..26]),decimal,10); # residue number # 6
for i from 2 to 7 do
MAT[j,i+5]:= m[i]; # MAT 7,8, 9 are coordinates
end do:
j:= j + 1;
end if;
end do:
j:= j - 1: # number of atoms
close(dataname):
len:=0:
if MAT[n_atoms, 5] <> "A" then
for i from 2 to n_atoms do
if MAT[i,6] < MAT[i-1,6] then
len:= len + MAT[i-1,6];
end if;
end do;
len:= len + MAT[n_atoms,6] # add last chain
else
len:= MAT[n_atoms,6]: # number of residues
end if:
len:= len + res_A :
# check last residue in case it is not complete
L1:=0:
for i from n_atoms by -1 to n_atoms-4 do
if MAT[ i,6] <> MAT[i-1,6] then L1:=L1+1 end if;
end do;
if L1 <> 0 then
len:= len - 1;
n_atoms:= n_atoms - L1;
printf("%s \n","Last residue incomplete");
end if;
printf("%s %a %s \n","There are ",len," residues");
################################################
|
| > |
# make array to hold results then calc angle phi
val_phi:= Vector(1..len):
for i from 1 to len do val_phi[i]:= 200 end do: # 200 so it is not plotted if empty
jend:= n_atoms:
while MAT[jend,4] = MAT[jend-1,4] do jend:= jend - 1 end do:
j:= 1: indx:= 1: resd:= 1: # calculate phi
while indx <= jend do # indx is incremented in angle_phi
val_phi[j]:= angle_phi(indx):
resd:= MAT[indx,2]:
j:= j + 1:
end do:
# make array to hold results then calc angle psi and print angles.
#
# Comment out printf statements to prevent printing angles.
#
val_psi:=Vector(1..len):
res_name:=Vector(1..len):
for i from 1 to len do val_psi[i]:=200 end do:
printf(" %s \n" ," atom residue phi psi ");
j:= 1: indx:= 2: resd:=1: # calculate psi, ignore ist residue
while indx < jend do
val_psi[j]:= angle_psi(indx):
res_name[j]:= MAT[indx-1,4]: # need names for some plots
resd:= MAT[indx,2];
printf("%5a %s %5a %4s %2s %4a %9.4g %9.4g \n",j,":",MAT[indx-1,2],MAT[indx-1,4],MAT[indx-1,5],
MAT[indx-1,6],val_phi[j],val_psi[j]):
j:= j + 1:
end do:
################################################
########### plot all residues #################
|
| > |
ss:=seq([val_phi[i],val_psi[i]],i=1..len):
p1:=plot([ss],style=point,color=black,axes=boxed,scaling=constrained,labels=["phi","psi"],
symbolsize=10,style=point,symbol=circle,view=[-180..180,-180..180],
tickmarks=[spacing(30),spacing(30)],axis=[gridlines=[majorlines=1,color=grey]],
axesfont=[times,12],font=[times,12], resolution=600,numpoints=1000,
title="All Residues "|| dataname ):
Solid_Lines():
print(display(p1,lines));
################################################
|
| > |
res_A:=Vector(1..len): # plot GLY
phi_A:=Vector(1..len):
psi_A:=Vector(1..len):
j:=1:
for i from 1 to len do
if res_name[i]="GLY" then
phi_A[j]:=val_phi[i]; psi_A[j]:=val_psi[i]: j:=j+1:
end if:
end do:
ss_A:=seq([phi_A[i],psi_A[i]],i=1..j-1):
p2:=plot([ss_A],color=black, axes=boxed, scaling=constrained,
labels=["phi","psi"], symbolsize=10,style=point,symbol=circle,
view=[-180..180,-180..180],tickmarks=[spacing(30),spacing(30)],
axis=[gridlines=[majorlines=1,color=grey]],axesfont=[times,12],font=[times,12],
resolution=600,numpoints=1000,title="Glycines "||dataname):
print(display(p2,lines));
################################################ |
| > |
j:=1:
for i from 1 to len do # plot PRO
if res_name[i]="PRO" then
phi_A[j]:=val_phi[i]; psi_A[j]:=val_psi[i]: j:=j+1:
end if:
end do:
ss_A:=seq([phi_A[i],psi_A[i]],i=1..j-1):
p3:=plot([ss_A],color=black, axes=boxed, scaling=constrained,
labels=["phi","psi"], symbolsize=10,style=point,symbol=circle,
view=[-180..180,-180..180],tickmarks=[spacing(30),spacing(30)],
axis=[gridlines=[majorlines=1,color=grey]],axesfont=[times,12],font=[times,12],
resolution=600,numpoints=1000,title="prolines "||dataname):
print(display(p3,lines));
################################################
|
| > |
j:=1:
for i from 2 to len do # plot pre PRO
if res_name[i]="PRO" then
phi_A[j]:=val_phi[i-1]; psi_A[j]:=val_psi[i-1]: j:=j+1:
end if:
end do:
ss_A:=seq([phi_A[i],psi_A[i]],i=1..j-1):
p4:=plot([ss_A],color=black, axes=boxed, scaling=constrained,
labels=["phi","psi"], symbolsize=10,style=point,symbol=circle,
view=[-180..180,-180..180],tickmarks=[spacing(30),spacing(30)],
axis=[gridlines=[majorlines=1,color=grey]],axesfont=[times,12],font=[times,12],
resolution=600,numpoints=1000,title="pre-prolines " ||dataname):
print(display(p4,lines));
end proc: # ramachandran
##################################################################### |
| > |
# now do the calculation
ramachandran(dataname); |
| Atom coords start at line 278 and there are 1733 atoms. pdb ends at line 2054 |
atom residue phi psi
1 : 12 THR A 5 174.1 50.44
2 : 16 GLY A 6 114.6 4.028
3 : 27 ARG A 7 -130.3 -46.57
4 : 34 PRO A 8 -61.35 -40.99
5 : 43 GLU A 9 -94.45 13.08
6 : 57 TRP A 10 -49.38 -28.84
7 : 65 ILE A 11 -63.48 -81.76
8 : 79 TRP A 12 -36.04 -46.57
9 : 87 LEU A 13 -52.09 -58.92
10 : 92 ALA A 14 -51.99 -46.44
11 : 100 LEU A 15 -58.83 -39.51
12 : 104 GLY A 16 -68.28 -37.09
13 : 111 THR A 17 -66.48 -48.5
14 : 116 ALA A 18 -53.57 -40.59
15 : 124 LEU A 19 -72.6 -48.1
16 : 132 MET A 20 -57.16 -50.85
17 : 136 GLY A 21 -68.8 -34.46
18 : 144 LEU A 22 -63.03 -49.8
19 : 148 GLY A 23 -54.42 -33.11
20 : 155 THR A 24 -67.03 -57.44
21 : 163 LEU A 25 -54.08 -32.3
22 : 175 TYR A 26 -64.06 -60.57
23 : 186 PHE A 27 -51.8 -57.56
24 : 194 LEU A 28 -40.19 -46.9
25 : 201 VAL A 29 -92.51 48.9
26 : 210 LYS A 30 -158.7 -9.583
27 : 214 GLY A 31 -110.4 -1.595
28 : 222 MET A 32 -45 -56.81
29 : 226 GLY A 33 -58.75 -83.99
30 : 233 VAL A 34 27.1 107.3
31 : 239 SER A 35 -101.2 -48.03 |
32 : 247 ASP A 36 -59.61 115.5
33 : 254 PRO A 37 -66.26 -33.96
34 : 262 ASP A 38 -49.99 -56.77
35 : 267 ALA A 39 -67.94 -35.84
36 : 276 LYS A 40 -44.64 -39.91
37 : 285 LYS A 41 -51.06 -63.07
38 : 296 PHE A 42 -40.25 -57.6
39 : 308 TYR A 43 -44.79 -71.43
40 : 313 ALA A 44 -37.14 -51.6
41 : 321 ILE A 45 -62.88 -63.47
42 : 328 THR A 46 -55.45 8.77
43 : 335 THR A 47 -120.5 -44.12
44 : 343 LEU A 48 -51.69 -47.85
45 : 350 VAL A 49 -42.03 -62.39
46 : 357 PRO A 50 -58.63 -49.53
47 : 362 ALA A 51 -47.31 -62.25
48 : 370 ILE A 52 -54.79 -48.51
49 : 375 ALA A 53 -48.64 -38.59
50 : 386 PHE A 54 -63.98 -45.97
51 : 393 THR A 55 -62.55 -37.42
52 : 401 MET A 56 -70.68 -49.74
53 : 413 TYR A 57 -62.06 -20.66
54 : 421 LEU A 58 -78.51 -49.22
55 : 427 SER A 59 -65.32 -27.14
56 : 435 MET A 60 -64.41 -46.53
57 : 443 LEU A 61 -65.24 -54.8
58 : 451 LEU A 62 -56.75 -26.72
59 : 455 GLY A 63 143.5 -73.16
60 : 467 TYR A 64 -22.11 -38.45
61 : 471 GLY A 65 -40.81 -77.29
62 : 479 LEU A 66 -58.61 173
63 : 486 THR A 67 -159.8 169.5
64 : 494 MET A 68 -114.5 95.13
65 : 501 VAL A 69 -89.72 126.7
66 : 508 PRO A 70 -87.01 108.7
67 : 519 PHE A 71 -146.4 123.1
68 : 523 GLY A 72 62.21 36.87
69 : 527 GLY A 73 129.8 -85.04
70 : 536 GLU A 74 -101.4 -179.3
71 : 545 GLN A 75 -89.38 117.2
72 : 553 ASN A 76 -105.2 145.3
73 : 560 PRO A 77 -75.71 141.7
74 : 568 ILE A 78 -147.1 93.62
75 : 580 TYR A 79 -64.02 84.17
76 : 594 TRP A 80 -61.78 -18.73
77 : 599 ALA A 81 -52.36 -34.77
78 : 610 ARG A 82 -56.9 -69.67
79 : 622 TYR A 83 -39.96 -39.4
80 : 627 ALA A 84 -53.75 -60.82
81 : 635 ASP A 85 -44.59 -74.77
82 : 649 TRP A 86 -42.29 -40.58
83 : 657 LEU A 87 -55.92 -33.45
84 : 668 PHE A 88 -96.17 -55.76
85 : 675 THR A 89 -49.87 -69.17 |
86 : 682 THR A 90 -35.43 -45.75
87 : 689 PRO A 91 -64.79 -59.34
88 : 697 LEU A 92 -40.08 -42.52
89 : 705 LEU A 93 -60.92 -57.56
90 : 713 LEU A 94 -45.34 -47.44
91 : 721 LEU A 95 -56.8 -41.1
92 : 729 ASP A 96 -54.18 -44.9
93 : 737 LEU A 97 -67.44 -63.29
94 : 742 ALA A 98 -47.89 -58.84
95 : 750 LEU A 99 -47.86 -46.47
96 : 758 LEU A 100 -55.98 -70.17
97 : 765 VAL A 101 -75.04 45.77
98 : 773 ASP A 102 9.889 73.64
99 : 778 ALA A 103 -87.38 144
100 : 786 ASP A 104 -59.89 127.9
101 : 795 GLN A 105 -40.11 -33.31
102 : 799 GLY A 106 -49.35 -63.34
103 : 806 THR A 107 -62.04 -37.24
104 : 814 ILE A 108 -53.02 -62.09
105 : 822 LEU A 109 -46.52 -54.84
106 : 827 ALA A 110 -62.82 -29.31
107 : 835 LEU A 111 -73.73 -41.79
108 : 842 VAL A 112 -65.08 -53.25
109 : 846 GLY A 113 -56.95 -31.52
110 : 851 ALA A 114 -63.66 -52.76
111 : 859 ASP A 115 -61.67 -40.69
112 : 863 GLY A 116 -49.57 -60.82
113 : 871 ILE A 117 -57.49 -32.69
114 : 879 MET A 118 -61.51 -73.09
115 : 887 ILE A 119 -52.51 -51.23
116 : 891 GLY A 120 -47.25 -52.51
117 : 898 THR A 121 -68.58 -24.6
118 : 902 GLY A 122 -69.1 -28.74
119 : 910 LEU A 123 -71.12 -62.56
120 : 917 VAL A 124 -46.85 -35.7
121 : 921 GLY A 125 -58.29 -57.87
122 : 926 ALA A 126 -77.03 35.94
123 : 934 LEU A 127 -149.4 1.234
124 : 941 THR A 128 -77.53 144.8
125 : 950 LYS A 129 -88.43 -48.9
126 : 957 VAL A 130 -60.94 115.7
127 : 969 TYR A 131 -50.94 -43.77
128 : 975 SER A 132 -66.76 -38.11
129 : 987 TYR A 133 -62.7 -33.73
130 : 998 ARG A 134 -43.56 -46.67
131 : 1009 PHE A 135 -72.61 -26.07
132 : 1016 VAL A 136 -63.07 -37.39
133 : 1030 TRP A 137 -76.45 -43.31
134 : 1044 TRP A 138 -44.95 -44.51 |
135 : 1049 ALA A 139 -62.9 -66.44
136 : 1057 ILE A 140 -47.79 -37.05
137 : 1063 SER A 141 -67.17 -55.55
138 : 1070 THR A 142 -51.08 -50.05
139 : 1075 ALA A 143 -44.76 -40.61
140 : 1080 ALA A 144 -61.14 -47.85
141 : 1088 MET A 145 -63.34 -57.55
142 : 1096 LEU A 146 -45.4 -28.24
143 : 1108 TYR A 147 -68.17 -59.71
144 : 1116 ILE A 148 -47.41 -63.08
145 : 1124 LEU A 149 -50.42 -36.06
146 : 1136 TYR A 150 -62.94 -71.4
147 : 1143 VAL A 151 -62.82 19.15
148 : 1151 LEU A 152 -119 -52.15
149 : 1162 PHE A 153 -72 -11.48
150 : 1173 PHE A 154 -101.4 -70.18
151 : 1177 GLY A 155 -57.88 -79.43
152 : 1188 PHE A 156 -37.81 -17.72
153 : 1195 THR A 157 -78.24 -53.51
154 : 1201 SER A 158 -54.26 -70.78
155 : 1210 LYS A 159 -46.28 -42.7
156 : 1215 ALA A 160 -54.85 -61.92
157 : 1224 GLU A 161 -73.95 63.63
158 : 1230 SER A 162 -169.2 37.46
159 : 1238 MET A 163 -150 -120
160 : 1249 ARG A 164 -91.86 149.4
161 : 1256 PRO A 165 -60.93 -29.76
162 : 1265 GLU A 166 -51.75 -68.77
163 : 1272 VAL A 167 -45.76 -68.68
164 : 1277 ALA A 168 -33.02 -65.77
165 : 1283 SER A 169 -52.66 -57.26
166 : 1290 THR A 170 -52.87 -52.46
167 : 1301 PHE A 171 -45.19 -57.07
168 : 1310 LYS A 172 -49.65 -45.9
169 : 1317 VAL A 173 -46.98 -78.71
170 : 1325 LEU A 174 -47.12 -50.02
171 : 1336 ARG A 175 -48.51 -49.72
172 : 1344 ASN A 176 -67.87 -42.83
173 : 1351 VAL A 177 -59.42 -63.77
174 : 1358 THR A 178 -37.15 -50.48
175 : 1365 VAL A 179 -60.01 -54.12
176 : 1372 VAL A 180 -61.56 -62.24
177 : 1380 LEU A 181 -40.52 -76.19
178 : 1394 TRP A 182 -35.55 -64.04
179 : 1400 SER A 183 -41.05 -43.06
180 : 1405 ALA A 184 -41.75 -38.02
181 : 1417 TYR A 185 -53.21 -71
182 : 1424 PRO A 186 -31.32 -45.6
183 : 1431 VAL A 187 -70.71 -56.5
184 : 1438 VAL A 188 -47.84 -50.34
185 : 1452 TRP A 189 -53.61 -53.77
186 : 1460 LEU A 190 -52.98 -68.42
187 : 1468 ILE A 191 -49.21 -32.56
188 : 1472 GLY A 192 -69.52 174.5
189 : 1478 SER A 193 -66.64 -21.96
190 : 1487 GLU A 194 -71.61 -24.08
191 : 1491 GLY A 195 -117.2 -122.8
192 : 1496 ALA A 196 -79.19 113.9
193 : 1500 GLY A 197 -66.67 88.73
194 : 1508 ILE A 198 -96.47 -65.87
195 : 1515 VAL A 199 -83.64 162.4
196 : 1522 PRO A 200 -88.17 170.4 |
197 : 1530 LEU A 201 -64.74 -16.85
198 : 1538 ASN A 202 -57.2 -36.08
199 : 1546 ILE A 203 -85.62 -71.16
200 : 1555 GLU A 204 -18.1 -71.91
201 : 1562 THR A 205 -38.68 -62.84
202 : 1570 LEU A 206 -57.3 -31.42
203 : 1578 LEU A 207 -69.48 -67.91
204 : 1589 PHE A 208 -52.78 -23.46
205 : 1597 MET A 209 -64.02 -52.76
206 : 1604 VAL A 210 -66.24 -51.62
207 : 1612 LEU A 211 -53.56 -28.94
208 : 1620 ASP A 212 -69.9 -74.4
209 : 1627 VAL A 213 -49.64 -31.51
210 : 1633 SER A 214 -77.89 -40.17
211 : 1638 ALA A 215 -69.92 -42.89
212 : 1647 LYS A 216 -81.87 -59.03
213 : 1654 VAL A 217 -77.11 -24.73
214 : 1658 GLY A 218 -65.02 -68.98
215 : 1669 PHE A 219 -51.87 -11.55
216 : 1673 GLY A 220 -79.18 -62.05
217 : 1681 LEU A 221 -61.17 -52.88
218 : 1689 ILE A 222 -47.45 -66.49
219 : 1697 LEU A 223 -54.31 -89.21
220 : 1705 LEU A 224 -30.68 -28.77
221 : 1716 ARG A 225 -88.64 24.88
222 : 1722 SER A 226 -125.7 153.7 |
 |
 |
 |
 |
|
