• Synopsis
• Problem
• Assumptions, Sketch and Definitions
  • Assumptions
  • Sketch
  • Definitions
• Solution
• Data
• Plots of Jib and Load Displacements
• Plot of Rope Stretch
• Load Drop and Dynamic Magnification
  • Load Drop
  • Dynamic Magnification Factor for Jib
  • Dynamic Magnification Factor of Surviving Rope
• Observations
  • Crane
  • Maple

HAMMERHEAD CRANE

By J.M. Redwood.

Synopsis

A compound oscillator, comprising two masses and two springs, is used to model the response of a big hammerhead crane and its load if one of its two reeves of steel wire ropes were to fail. The response is used to obtain a "back of the envelope" estimate of how far the load would fall, and check that the crane would not be overstressed

Problem

A big hammerhead crane is being considered for lifting some very valuable, heavy loads and lowering them delicately into position. The lifting hook is suspended from the crane's cantilever jib by two independent reeves of steel wire rope. Either is capable of supporting the load alone. If one reeve were to fail suddenly:

a. How far might the load drop before being arrested by the surviving reeve? (This would be useful for estimating the severity of damage to the load.)

b. Would the oscillations of the lifting hook and load overstress the crane's jib? That is, would the dynamic magnification factor exceed the impact factor for which the crane had been designed?

Assumptions, Sketch and Definitions

Assumptions

a. Assume that the crane manoeuvres the load very slowly at all times. (This would be normal practice with a valuable, heavy load.)
b. Assume that the failure is instantaneous, so that the full weight of the load is suddenly transferred to the surviving rope.
c. Assume that immediately before the failure, both ropes are equally loaded and stretched.

d. Assume that damping can be ignored. (This assumption means that the drop and dynamic magnification would be overestimated, and therefore errs on the safe side.)
e. Assume that the coupled masses and linear springs, as shown in the sketch, are an adequate model of the loaded crane. The crane's jib, without a load, is represented by a mass M1 and spring of stiffness S1. The load is represented by a mass M2 suspended from a spring of stiffness S2, representing the surviving rope reeve .

Sketch

The sketch below was made using Microsoft Windows Paintbrush and pasted into this worksheet as an OLE2 object.

Definitions

a. Let the displacements be measured from the equilibrium positions of the masses representing the load and the jib.
b. Let displacements of the masses representing the load and the jib be positive when measured in the upward direction.

c. Let the forces acting on the masses representing the load and jib be positive when acting in the upward direction.

Solution

The equations of motion, eq 1 and eq 2, are obtained by equating the forces acting on the masses M1 and M2 to their mass-accelerations as follows.

> restart;

> eq1 := M1*diff(x1(t),t,t) + (S1+S2)*x1(t) - S2*x2(t) = 0;

> eq2 := M2*diff(x2(t),t,t) + S2*x2(t) - S2*x1(t) = 0;

The initial conditions are:

a. The displacement and velocity of the crane's jib are both zero.

b. The load's velocity is zero.

c. Before one of the ropes fails, each rope carries half the load and is stretched an amount from its unloaded condition. After failure, the remaining rope has been stretched an additional amount equal to d because it carries twice the load it carried previously. Thus on failure, the equilibrium position of the load is displaced down instantaneously by d , and the initial condition for the load's displacement immediately after the failure is, therefore:

> X2 := (M2*g/2)*(1/S2);

The equations defining the initial conditions for the crane's jib and the load are shown below, and are used with the command "dsolve" to solve the equations of motion.

> ini1 := D(x1)(0) = 0, x1(0) = 0;

> ini2 := D(x2)(0) = 0, x2(0) = X2;

> sols := dsolve({eq1,eq2,ini1,ini2},{x1(t),x2(t)}):

> sols1 := convert(sols,trig):

Data

Substitute following data in SI units:

M1 = 4.298*10^4 (derived from S1 and the natural frequency of the jib Fn = 2.12 Hz calculated during the crane's design),

(The actual mass of the crane's jib was 1.4*10^6 and, on the assumption that the jib behaves as a slender cantilever, the maximum equivalent mass M1 could be estimated as M1 = 2.261*10^5. However, this gives a lower natural frequency for the jib, and therefore yields lower stresses.)

S1 = 7.626*10^6 (derived from a deflection test of the jib),

M2 = 9*10^4 (measured maximum mass of the lifting hook and load),

,

where m = no of reeves, n = no of falls per reeve, E = Young's Modulus for the rope, d = diameter of rope and L = length of rope, (447m with the crane at maximum radius and with the hook close to the ground).

> m := 1;

> n := 4;

> E := 6.8*10^10;

> d := 0.044;

> L := 447;

> g := 9.80665;

> S1 := 1.214*10^6/0.1592; # force/deflection

> Fn := 2.12;

> M1 := S1/((2*Pi*Fn)^2); # stiffness/(angular nat freq)^2

> M2 := 9*10^4;

> S2 := (m*n^2*E*Pi*d^2/4)/L ; # rope formula

Plots of Jib and Load Displacements

Display the solutions to the equations of motion and plot them over the first few oscillations

> sols2 := simplify(sols1);

> x1(t) := subs(sols2,x1(t)):

> x2(t) := subs(sols2,x2(t)):

> with(plots):

> plot([x1(t),x2(t)], t=0..3, color=[red,blue], title="Displacement of load in blue, jib in red", labels=[seconds,metres]);

Warning, the name changecoords has been redefined

The displacement of the load starts from its initial condition X2, and then oscillates about the new equilibrium position. Initially, the jib rises from its equilibrium position (i.e. zero displacement) because the tension applied by the surviving rope reeve is half that applied by the two ropes just prior to the failure. Thereafter, it performs a complicated oscillation about its equilibrium position.

Plot of Rope Stretch

Display the rope stretch, which is the difference between load and jib positions.

> plot((x2(t)-x1(t)), t=0..3, color=COLOR(RGB, 0, 0.4, 0.1), title="Stretch of the rope = load - jib displacements", labels=[seconds,metres]);

The dynamic stretch of the surviving rope is a complicated oscillation about the static stretch and is a measure of the dynamic load imposed on the rope reeve.

Load Drop and Dynamic Magnification

At this point, it is sensible to recognise that the data are approximate, and the results produced by the model can only be accurate to 3 figures, at best. The "Digits" command is therefore used to set this value.

> Digits := 3;

Load Drop

If one of the ropes fails, the load will drop from the initial position, where it is X2 above the final equilibrium position, to X2 below the equilibrium position, as indicated by the plot. Thus the load will drop by twice X2 from its initial position, i.e.

> `Load Drop` := evalf(2*X2);

Dynamic Magnification Factor for Jib

The dynamic magnification factor is the ratio of the maximum strain under dynamic conditions to the static strain. For the crane's jib, it is the total displacement, when the jib is deflected most after the rope failure compared to its total displacement prior to failure of a rope. That is, the dynamic magnification for the jib is given by

> f1 := '((M1 + M2)*g/S1 + `max(x1)`)/((M1+M2)*g/S1)';

(Back quotes are used to convert max(x1 ) into a name in the expression above for f1 . Single quotes are used to delay evaluation of this expression, so that it appears symbolically.)

The plot of x1(t) shows that its maximum value is about 0.08, which can also be found using the "maximize" command.

> `max(x1)` := maximize(x1(t),t,'infinite');

> f1 := evalf(f1);

Dynamic Magnification Factor of Surviving Rope

Similarly, the dynamic magnification factor for the surviving rope reeve is the maximum stretch of the rope (i.e. maximum displacement of the load minus displacement of the jib) compared to its stretch before failure of the other rope reeve. It is given by

> f2 := '((M2*g/S2 + `max (x2-x1)`)/(M2*g/S2))';

The plot of displacement of load minus displacement of the jib shows that its greatest value is about 0.12 metre. This is, of course, the initial value of x2(t), i.e. X2.

> `max (x2-x1)` := evalf(X2);

> f2 := evalf(f2);

>

Observations

Crane

a. Following a sudden failure of one rope reeve, the load would fall about 0.24 m.

b. The dynamic magnification factor for the static strain of the crane's jib is 1.47, which is slightly less the impact factor of 1.5 used for its design. On this basis, the crane would not be overstressed and could withstand the effect of a sudden failure of a rope reeve.

c. The dynamic magnification factor for the surviving rope reeve is 1.49. This is about the same as the impact factor used for the design of the pulleys, bearings, rope anchors, winches, machinery, etc. On this basis they should withstand the effect of a sudden failure of the other rope reeve. The factor of safety of the ropes on this crane was 6, so the surviving rope should withstand the effect of the other reeve failing. However, this judgement could only be made by specialists after considering the ropes' condition, installation dates, test results, etc.

d. In practice, the "back of an envelope" calculations shown above would be used only as the basis for deciding to spend significant sums on detailed analyses, inspections and certification by crane specialists before lifting the very valuable, heavy loads postulated. It is emphasised that this worksheet should NOT be used for checking a crane's design.

Maple

a. The symbolic solution to the pair of simultaneous differential equations describing the motion of the crane's jib and the load is long and complicated. It can be viewed by replacing the colon following the command "dsolve" with a semicolon. Yet Maple produces this solution with ease. The reader is invited to try obtaining the solution by hand.

b. A symbolic solution of the equations of motion was obtained, mainly because it allowed a plot of the stretch in the surviving rope to be produced easily, and because the plots produced appear rather smoother, than those available after solving the equations of motion numerically. It also allowed the "maximize" command to be demonstrated. However, since the accuracy of the data is limited, the maximum value of x1(t) read from the plot is good enough.

c. Users of Maple 6.01 will be unable to use the "maximize" command. As mentioned above, the value of x1(t) obtained from a plot is sufficiently accurate.

Disclaimer:

While every effort has been made to validate the solutions in this worksheet, Waterloo Maple Inc. and the contributors are not responsible for any errors contained and are not liable for any damages resulting from the use of this material.