• Introduccin:
• Conceptos Bsicos:
• Clases y Frecuencias
• Grficos de datos:
• Medidas de Dispersin

MAPLE

MANU AL BASICO

Para Estudiantes y Profesores

MAPLE V Versin...:. 5.3

Captulo IX - Estadstica

Documento: Maple Manual Ecuaciones Diferenciales

Captulo: IX - Estadstica

Elabor: Csar Ivn Tinoco.

Versin: 30 de Junio del 2.000

Introduccin:

En estadstica estudiamos cierto tipo de variables aleatorias las cuales pueden ser discretas o continuas y estan agrupadas en un conjunto de datos que llamamos muestra. Los datos pueden ser Discretos, cuando dichas variables slo pueden tener nmeros Naturales o

Continuas, cuando el conjunto de datos puede ser un subconjunto de los nmeros reales.

Para tener acceso a procedimientos estadsticos predefinidos es necesario usar la librera stats , que adiferencia de las otras libreras usadas hasta el momento, tiene sub libreras:

> restart:
with(stats);

Las cuales tienen los siguientes objetivos:

anova........: Anlisis de varianza

describe....: Anlisis y descripcin de datos

fit..............: Regresiones Lineales

importdata.: Importar datos

random......: Generacin de nmeros aleatorios sobre una distribucin

statevalf.....: Evaluacin numrica de evaluaciones

statplots.....: Graficas de Funciones

transform...: Manipulacin de funciones

Conceptos Bsicos:

Inicialmente usaremos la sub librera describe, para obtener informacin estadstic bsica de los datos.

> restart:with(stats[describe]);

Supongamos que tenemos la siguiente muestra o conjunto de datos los que representan las estaturas de 50 mujeres.

> datos:=[65,63,65,63,69,67,53,58,60,61,64,65,64,72,68,66,55,57,60,62,64,65,64,71,68,66,56,59,61,62,63,65,63,70,67,66,57,59,61,62,64,64,63,69,67,66,58,60,61,62];
`Total de datos..: `,count(%);

Conteo de datos. count( argumento ) . Lo que significaria nops en calculo numrico:

> count(datos),nops(datos);

Sumatoria de datos. Lo que significara sum( argumento ) , en calculo numrico.

> `La Sumatoria es..: `,sumdata(datos);
sum(datos[i],i=1..nops(datos));

El valor de la variable aleatoria que ms se repite dentro de la lista se denomina Moda y se calcula con la orden: mode ( argumento ) .

> `La Moda es..: `,mode(datos);

El valor de la variable aleatoria que supera a no ms de la mitad de los datos y a la vez es superado por no ms de la mitad se llama Mediana y se calcula: median ( argumento )

> `La mediana es..: `,evalf(median(datos),4);

La Media aritmetica o promedio es el resultado de dividir la sumatoria de datos entre el nmero de datos y se calcula: mean ( argumento ) .

> `La media es..: `,evalf(mean(datos),4);

El rango son los lmites de los datos, es decir, el valor ms pequeo y el ms grande de los datos. y se calcula: range ( argumento ).

> `El Rango es..: `,range(datos);

La media geometrica es la raiz n-esima del producto de los datos.y se calcula: geometricmean( argumento ) .

> `La media geomtrica es..: `,evalf(geometricmean(datos),4);

Clases y Frecuencias

Cuando un conjunto de tatos es demasiado grande, podemos simplificar el anlisis de datos agrupando el conjunto en intervalos, lo que se denomina una clase, continuemos con el ejemplo inicial y agrupemos dicho conjunto en clases.

> restart:
with(stats[transform]):with(stats[describe]):
datos:=[65,63,65,63,69,67,53,58,60,61,64,65,64,72,68,66,55,57,60,62,64,65,64,71,68,66,56,59,61,62,63,65,63,70,67,66,57,59,61,62,64,64,63,69,67,66,58,60,61,62]:

Warning, the protected name apply has been redefined and unprotected

Para hacer algunas transformaciones a la lista de datos usamos la sub librera transform

Para ordenar los dados usamos la orden satsort ( argumento )

> statsort(datos);

Para agrupar los datos de acuerdo a la frecuencia con que sus elementos se repiten usamos la orden tally ( argumento ) .

> datos1:=statsort(tally(datos));

Weight ( a...b, n), nos indica que los elementos a..b se repiten n veces en la lista. Tambien lo podemos usar para definir una lista.

> datos1:=[Weight(3,2),5,8,4];
`Cantidad..: `,count(datos1);
datos2:=[Weight(5..7,10),5,8,4];
`Cantidad..: `,count(datos2);

Podemos averiguar la frecuencia de un conjunto de datos en una lista, con la orden frequency ( argumento ). Los datos deben estar agrupados.

> datos2;
frequency(datos2);

Si quisieramos transformar la escala en que observamos la frecuencias, usamos la orden scaleweight ( n ) , que modifica la escala de la frecuencia a n . Por ejemplo queremos ver la frecuencia de la lista datos2 en trminos de la cantidad de datos.

> scaleweight[1/count(datos2)](datos2);

Grficos de datos:

Al igual que en otras situaciones numricas, en estadstica los grficos juegan un gran papel. en Maple los podemos representar usando la librera,

> restart:
with(stats[statplots]);

La grafica de datos de acuerdo a la frecuencia con que estos se presentan en la lista se puede calcular con la orden scatterplot , la cual tiene la siguinete sintxis:

Orden ........: scatterplot

Sintxis ......: scatterplot ( lista, formato = [n,l] )

Propsito ...: Presenta el grfico correspondiente a los datos de la lista en el formato establecido en el argumento, organizando la presentacin en clases [ n , l] .

> datos:=[65,63,65,63,69,67,53,58,60,61,64,65,64,72,68,66,55,57,60,62,64,65,64,71,68,66,56,59,61,62,63,65,63,70,67,66,57,59,61,62,64,64,63,69,67,66,58,60,61,62]:

> scatterplot(datos,title=`Datos`,color=magenta,view=[50..75, 0..2]);

Ahora los datos presentados en forma aglomerada.

> scatterplot(datos,format=agglomerated,title=`Datos Aglomerados`);

Veamos los datos en forma simtrica

> scatterplot(datos,format=symmetry,title=`Simetrica`);

El histograma presenta un grfico de la las frecuancias de los datos.

Orden ........: histogram

Sintxis ......: histogram ( lista, argumento=n ,opciones)

Propsito ...: Presenta el grfico de barras, correspondiente a los datos de la lista de acuerdo al nmero del argumento, con las opciones normales de la orden plot .

> histogram(datos,title=`Histograma de Frecuencias`,color=cyan);

> histogram(datos,area=1,title=`Histograma areas Iguales`,color=cyan,view=[52..75, 0..0.5]);

Ahora una grfica donde presentamos ms informacin que los simples datos.

Orden ........: boxplot

Sintxis ......: boxplot ( lista, argumento=n ,opciones)

Propsito ...: Presenta una caja donde con tres lineas caractersticas de los datos:

La lnea del centro representa la Mediana.

Las lineas superior e inferior representa el tercer cuartil y el primer cuartil.

Cuando se agrega el parmetro Shit=1 aparecen las lineas representando el rango

> boxplot(datos,shift=1,color=magenta,title=`Acumulacin, rango, Mediana y cuartiles`);

Podemos cambiar la presentacin:

> xyexchange(boxplot(datos,color=magenta));

Medidas de Dispersin

Las medidas de dispersin representan el grado en que las variables tienden a extenderse o concentrarse al rededor de un valor. Estos son, entre otros, desviacin media, desviacin tpica, varianza y coeficiente de variacin.

La diferencia entre el valor y la media se denomina desviacin media y se calcula en Maple con la orden: meandeviation( argumento ).

> restart:with(stats[describe]):
Desviacion:=meandeviation([3,4,4,7,7,7,8.]);

> with(stats[statplots]):
boxplot([3,4,4,7,7,7,8],color=red);

La desviacin tpica es la raz cuadrada de la media artmetica de los cuadrados de las desviaciones respecto a la media. Se calcula standarddeviation( argumento)

> Destandrard:=standarddeviation([3,4,4,7,7,7,8.]);

La varianza es la media artmetica de los cuadrados de las desviaciones respecto a la media. y se valcula: variance( argumento )

> Varianza:=variance([3,4,4,7,7,7,8.]);

El coeficiente de variacin es la razn entre la desviacin tpica y la media artmetica. Se calcula

coefficientofvariation( argumento ).

> Cfvariancion:=coefficientofvariation([3,4,4,7,7,7,8.]);

Calcular las medidas de desviacin y dispersin del siguiente conjunto de datos. Realizar los graficos de distribucin de frecuencias.:

> restart:with(stats[describe]):
datos:=[165,166,168,160,170,166,166,172,174,172,174,172,161,165,165,166,167,168,169,170,170,166,166,165,170,176,172,165,165,166,171,167,179,165,167,171,171,172]:

> with(stats[transform]):statsort(datos);
`Total de datos..: `,count(datos);
`Suma de datos...: `,sumdata(datos);
Digits:=6:
`Media Artmetrica..: `,evalf(mean(datos));
`Media Geomtrica..: `,evalf(geometricmean(datos));
`Mediana.........: `,evalf(median(datos));
`Moda............: `,evalf(mode(datos));
`Rango...........: `,range(datos);
`Desviacin Estandar.: `,evalf(standarddeviation(datos));
`Desviacin Media..: `,evalf(meandeviation(datos));
`Coeficiente de variacin..........: `,evalf(coefficientofvariation(datos));
`Varianza......:`,evalf(variance(datos));

Warning, the protected name apply has been redefined and unprotected

> with(stats[statplots]):
histogram(datos,title=`Histograma de Frecuancias`,color=pink);

Los cuartiles, deciles y porcentiles son una representacin de la mediana en rangos especficos de datos, cuatro, diez y cien partes de la muestra.

En Maple se pueden calcular con la orden quartile[n](datos, arg) ., decile, percentile . Donde n representa el ordinal del cuartil, decil o percentil.

> with(stats):
evalf(median(datos));
quartile[2](datos);

Warning, these names have been redefined: anova, describe, fit, importdata, random, statevalf, statplots, transform

Como una muestra tiene 3 quartiles, los podemos ver por medio de una secuancia.

> seq(quartile[i](datos),i=1..3);

Lo mismo sucede con los deciles y porcentiles, observe:

> decile[5](datos);
seq(decile[i](datos),i=1..9);

> percentile[30](datos);
seq(percentile[i*10](datos),i=1..9);

La distribucin standrar de un conjunto de datos se calcula la orden pdf de la librera statevaf . Estos datos se usan para hacer una representacin grfica para el anlisis.

Orden ........: statevvalf

Sintxis ......: statevalf ( f uncin , distribucin )( argumento )

Propsito ...: Calcula la funcin en terminos de la distribucin para los datos del argumento .

cdf Funcin densidad acumulada

icdf Funcin inversa

pdf Funcin de Probabilidad

> with(stats):
`Distribucin Estandar`:=evalf(standarddeviation(datos));
ppdf:=statevalf[pdf,normald]:
plot(ppdf,-4..6,title=`Distribucin Normal`);

Warning, these names have been redefined: anova, describe, fit, importdata, random, statevalf, statplots, transform

> `Distribucin Estandart`:=evalf(standarddeviation(datos));
pcdf:=statevalf[cdf,normald]:
plot(pcdf,-4..6,title=`Distribucin Acumulada`);

>

>