• 1. Introduction and fundamental concepts.
• 2. Symbolic calculation
  • 2.1 One-soliton solution
  • 2.2 Two-soliton solution
• 3. Visualisation
  • 3.1. One-soliton solution
  • 3.2. Two-soliton solution (Scattering)
• 4. Conclusions
• 5. Appendix: Catching the soliton

Solitons of KdV Equation

by Constantin Rasinariu, Ph.D.

Columbia College Chicago

Department of Science and Mathematics

600 S. Michigan Ave

Chicago, IL 60605
E-mail: crasinariu@popmail.colum.edu

1. Introduction and fundamental concepts.

Definition. A soliton is a localized traveling wave that scatters elastically.

One of the most studied nonlinear differential equation in mathematical physics is the Korteweg-de Vries

equation (KdV) :

.

KdV equation has solitonic solutions.

This one-dimensional equation (that is one spatial dimension plus time) is completely

integrable and gives rise to an infinite number of conservation laws.

Solutions of KdV equation can be systematically obtained from solutions of of the free particle
Schroedinger equation:

,

via the Wronskian formula

where

is the Wronkian determinant composed of whereas stands for

for , and for .

2. Symbolic calculation

> restart:

> with(linalg):

Warning, the protected names norm and trace have been redefined and unprotected

We design a simple procedure to compute the solution of the KdV equation, once the Wronskian

determinant is given:

> Soliton:=proc(w)
local L;
L := ln(w);
RETURN( simplify(2*diff(L,x$2)) )
end;

>

2.1 One-soliton solution

We consider where corresponds to a negative energy E of associated Schroedinger equation.

> xi:= k*(x-4*k^2*t);

> psi:= cosh(xi);

The Wronksi matrix is

> MW1:=Wronskian([psi],x);

and its determinant reads:

> W1:=det(MW1);

Therefore we obtain :

> u1:=Soliton(W1);

Is this result a solution of the KdV equation?

> KdV:=diff(u(x,t),t)+6*u(x,t)*diff(u(x,t),x)+diff(u(x,t),x$3);

> simplify(subs(u(x,t)=u1,KdV) );

>

2.2 Two-soliton solution

We consider in this case where ,

> xi[1]:= k[1]*(x-4*k[1]^2*t);xi[2]:= k[2]*(x-4*k[2]^2*t);

> psi[1]:=cosh(xi[1]); psi[2]:= sinh(xi[2]);

The Wronski matrix:

> MW2:=Wronskian([psi[1],psi[2]],x);

has the determinant:

> W2:=det(MW2);

and the corresponding two-soliton solution:

> u2:=Soliton(W2);

Check that it is a solution of KdV equation:

> KdV;

> simplify(subs(u(x,t)=u2,KdV) );

>

3. Visualisation

3.1. One-soliton solution

The simplest one-soliton solution of KdV is:

> u1;

Then we can graph the solution. Below is presented a static soliton with k = 0.5, t = - 10.

> with(plots):

Warning, the name changecoords has been redefined

> plot(subs({k=.5,t=-10},u1), x=-20..20,thickness=2);

Or, this solution can be animated, to emphasise the propagating nature of the solution soluion:

> animate(
subs(k=.5,u1),x=-20..20, t=-10..10,
numpoints=200,frames=50,color = red,thickness=2);

> soliton1:=%:

> soliton2:=animate(
subs(k=1,u1),x=-45..45, t=-10..10,
numpoints=300,frames=50,color = blue):

The speed and the amplitude of the soliton depend on the value of k .

> display(soliton1,soliton2);

>

3.2. Two-soliton solution (Scattering)

> u2;

> plot(
subs({k[1]=0.5, k[2]=1., t=-10},u2),x = -45..45,
color=yellow, thickness=2, numpoints=300);

> animate(
subs({k[1]=0.5, k[2]=1.},u2),x = -45..45, t= -10..10,
color=yellow, thickness=2, numpoints=300,frames=50);

> soliton22:=%:

> display(soliton1,soliton2,soliton22);

After a collision, solitons remarkably regain their original shape and velocity. A phase shift (i.e. a change in the position they would have reached without interaction) is the only remaining effect of the scattering.

>

4. Conclusions

(a) One of the most exciting features of the nonlinear evolution equations of the integrable models is that they posses localized nonlinear waves called solitons as solutions.
(b) Solitons scatter elastically, exhibiting striking stability properties through a balance of dispersion and nonlinearity. These features are clearly exposed in many-soliton collisions. After a collision, solitons remarkably regain their original shape and velocity. A phase shift (i.e. a change in the position they would have reached without interaction) is the only remaining effect of the scattering.
(c) The conservation laws which fully determine the dynamics of the integrable systems are also responsible for keeping both the shape and the size of soliton waves invariant. This provides a conceptual link to integrable models as a natural setup for the theory of solitons.

5. Appendix: Catching the soliton

Soliton on the Scott Russell Aqueduct on the Union Canal near Heriot-Watt University, 12 July 1995.