• Synopsis
• Introduction
• Example 1. A Vibrating String
  • Ratio of the Mean Energies 1
  • Fundamental Frequency 1
    • a. Assume that the initial deflected shape of the string is a sine curve.
    • b. Assume that the initial deflected shape of the string is a parabola.
    • c. Assume that the initial deflected shape of the string is a triangle.
  • Comparisons
• Example 2. A Vibrating String with Mass Attached
  • Ratio of the Mean Energies 2
  • Fundamental Frequency 2
    • a. Assume that the initial deflected shape of the string is a sine curve.
    • b. Assume that the initial deflected shape of the string is a parabola.
    • c. Assume that the initial deflected shape of the string is a triangle.
  • Comparisons
• Observations

LORD RAYLEIGH'S PRINCIPLE

By J.M. Redwood

Synopsis

This worksheet uses two examples of a vibrating elastic string to illustrate Lord Rayleigh's principle for estimating the fundamental frequency.

Introduction

 The principle enunciated by Lord Rayleigh (1842 - 1919), physicist and mathematician, may be stated as: "The distribution of the potential and kinetic energies of a conservative, elastic system in the fundamental mode of vibration is such that the frequency is a minimum."  This leads to where:

and  

 In the above equations, represents the coordinates of a conservative, elastic system with a finite number of degrees of freedom and having the minimum fundamental frequency, , while represents the coordinates of that system given any reasonable initial displacement.  V_bar and T_bar represent the system's mean potential and kinetic energies respectively.  The closer the assumption for displacement is to reality, the closer is the approximation of to .

 The principle applies to both discrete and continuous elastic systems and can be extended to obtain the higher frequencies.

 The application of Lord Rayleigh's principle is illustrated in this worksheet with two examples: one of a vibrating elastic string, and the other of a mass attached to the middle of the same string.

Example 1.  A Vibrating String

 An elastic string of length l is held between two clamps under tension and is vibrating freely and without friction in the transverse horizontal (x, y) plane.  The string is uniformly elastic, has a uniform cross-section and a linear density of .  Approximations, , to its fundamental frequency of vibration are obtained below.

Ratio of the Mean Energies 1

>

restart;

 Consider an element of the string of length , approximately equal to .  Its mass is and its transverse velocity is .  The kinetic energy of the element is given by , whence

>	eq1 := Diff(T,x) = rho/2*(Diff(y,t))^2;

 The kinetic energy of the whole string is obtained by integration,

>	eq2 := int(lhs(eq1),x) = Int(rhs(eq1),x=0..l);

 Hence, the mean kinetic energy over one cycle of the vibration is

>	eq3 := T_bar = Int(rhs(eq2),t=0..2*Pi/omega[a])/Int(1,t=0..2*Pi/omega[a]);

 The transverse component of tension acting on the element is .  The transverse displacement of the element (relative to an element of the string adjacent to it) is .  So the transverse stiffness, S, is given by .  But , therefore .
 The potential energy (strain energy) of the element is , hence = , because approximately equals .  Writing , the potential energy of the element becomes , whence

>	eq4 := Diff(V,x) = (tau/2)*Diff(y,x)^2;

 The potential energy of the whole string is obtained by integration, thus

>	eq5 := int(lhs(eq4),x) = Int(rhs(eq4),x=0..l);

 The mean potential energy over one cycle of the vibration is

>	eq6 := V_bar = Int(rhs(eq5),t=0..2*Pi/omega[a])/Int(1,t=0..2*Pi/omega[a]);

 It follows immediately that

>	eq7 := lhs(eq6)/lhs(eq3) = rhs(eq6)/rhs(eq3);

 By Lord Rayleigh's principle, .

 

Fundamental Frequency 1

 Assuming that the type of vibration is a simple periodic motion

>	y := f(x)*sin(omega[a]*t);

 Since the system is conservative,

>	T_bar := V_bar;

>	eq8 := value(eq7);

 The boundary conditions are that the string's deflections are zero at the end clamps.  Furthermore, since the string has no resistance to bending, the slope of the string at the clamps may take any value.  A sine curve, or parabola, or a triangular shape would satisfy these conditions.  Observation of the vibrating string indicates that its shape is a sine curve, or a parabola.

a.  Assume that the initial deflected shape of the string is a sine curve.

 Let the sine curve be given by

>	f(x) := sin(Pi*x/l);

>	ans1 := solve(eq8,{omega[a]});

 The "exact" fundamental frequency, , for this case may be found by solving the one-dimensional wave's partial differential equation.  It is identical to  found above.  However it is usually expressed as , where = elastic strain x .  This is related to found above by the following identities: = stress x area, = density x area, and stress = elastic strain x E, where c is the speed of a stress wave, or sound, in the material and E is Hooke's modulus for the material.

b.  Assume that the initial deflected shape of the string is a parabola.

 Let the parabola be given by

>	f(x) := l-(x-l/2)^2/(l/4);

>	ans2 := solve(eq8,{omega[a]});

c.  Assume that the initial deflected shape of the string is a triangle.

 Let the two sides of the triangle be given by f1(x) when 0<= x < = l/2, and by f2(x) when l/2 < x <= l.
 The integrals in equation 8 are now split to suit the values of x just defined, and f1(x) and f2(x) are allocated accordingly.

>	eq9 := 1 = tau*(int(diff(f1(x),x)^2,x = 0 .. l/2) + int(diff(f2(x),x)^2,x = l/2 .. l))/      omega[a]^2/(rho*(int(f1(x)^2,x = 0 .. l/2) + int(f2(x)^2,x = l/2 .. l)));

 Assuming that the equations of the triangle's sides are

>	f1(x) := 2*x/l;

>	f2(x) := 2*(1 - x/l);

>	ans3 := solve(eq9,{omega[a]});

Comparisons

 Observing that the order of solutions obtained by the solve command is machine dependent, a function is now created that takes this into account when producing ratios of the fundamental frequencies found above,

>	fr := (a,b,c,d)-> sqrt(op([1,2],a)^2/op([1,2],c)^2):

The fundamental frequency resulting from parabolic initial deflection of the string compared with that obtained with a sine curve, is 0.7% greater as shown by

>	evalf(fr(ans2,ans1));

 The fundamental frequency resulting from the triangular initial deflection of the string compared with that obtained with a sine curve is approximately 10.3% greater as shown by

>	evalf(fr(ans3,ans1));

>	unassign('y','T_bar','V_bar','f(x)','f1(x)','f2(x)');

Example 2.  A Vibrating String with Mass Attached

 The string considered in example 1 above is firmly attached to a mass, m, at its mid-length.  The centre of the mass surrounds the point of attachment, and the mass rests on a frictionless, horizontal surface.  The string and the mass are vibrating freely and without friction in the transverse horizontal (x, y) plane.  Approximations, , to the fundamental frequency of vibration are obtained below.

Ratio of the Mean Energies 2

 The only potential energy in the system is that stored in the stretched string.  Therefore the mean potential energy is identical to that obtained in example 1. The kinetic energy of the system comprises the kinetic energy of the string, as obtained in example 1, plus the kinetic energy of the mass.  The kinetic energy of the mass is given by

>	eq10 := T[m] = m/2*(Diff(y,t))^2;

The kinetic energy of the string is given by equation 2 above, so the kinetic energy of the system is

>	eq11 := lhs(eq2)+lhs(eq10) = rhs(eq2) + rhs(eq10);

 The mean kinetic energy over one cycle of the vibration is

>	eq12 := T_bar = Int(rhs(eq11),t=0..2*Pi/omega[a])/Int(1,t=0..2*Pi/omega[a]);

 The mean potential energy over one cycle of vibration  is given by equation 6.  Hence, the ratio of the mean potential to mean kinetic energy is

>	eq13 := lhs(eq6)/lhs(eq12) = rhs(eq6)/rhs(eq12);

Fundamental Frequency 2

 Again, assuming that the type of vibration is a simple periodic motion

>	y := f(x)*sin(omega[a]*t);

>	eq14 := value(eq13);

 Since the system is conservative,

>	V_bar := T_bar;

>	eq14 := simplify(eq14);

 The boundary conditions are the same as in the first example, namely that the string's deflections at the end clamps are zero, and its slope can take any value at these points.  A sine curve, a parabola, or a triangle would satisfy these conditions.

a.  Assume that the initial deflected shape of the string is a sine curve.

 Let the sine curve be given by

>	f(x) := sin(Pi*x/l);

 Evaluating equation 14 at the mid-length of the string where the mass is attached,

>	eq15 := eval(eq14,x=l/2);

>	ans4 := solve(eq15,{omega[a]});

b.  Assume that the initial deflected shape of the string is a parabola.

Let the parabola be given by

>	f(x) := l-(x-l/2)^2/(l/4);

 Again evaluating equation 14 at the mid-length of the string,

>	eq15 := eval(eq14,x=l/2);

>	ans5 := solve(eq15,{omega[a]});

c.  Assume that the initial deflected shape of the string is a triangle.

 Let the two sides of the triangle be given by f1(x) when 0 <= x <=  l/2, and by f2(x) when l/2 < x <= l.  Noting that equation 14 is the same as equation 8, but with an extra term in the denominator, equation 15 becomes the same as equation 9, but with a term for the mass, m, added to the denominator.

>	eq15 := lhs(eq9) = numer(rhs(eq9))/(denom(rhs(eq9)) + omega[a]^2*m*(piecewise( x<=l/2, f1(x)^2, l/2<x,(f2(x)^2))));

 Let the equations of the triangle's sides be given by

>	f1(x) := 2*x/l;

>	f2(x) := 2*(1 - x/l);

 Evaluating equation 15 at the string's mid-length,

>	eq16 := eval(eq15,x=l/2);

>	ans6 := solve(eq16,{omega[a]});

Comparisons

1.  The ratio of the mass to that of the string determines which initial deflection produces the lowest fundamental frequency; that is, the one closest to the true fundamental frequency.  This is illustrated by the plot below showing the ratio of fundamental frequencies for pairs of different initial deflections, expressed as a function of the mass ratio.

2.  For all values of the mass ratio, the ratio of fundamental frequencies is less for the sine curve and triangular initial deflection pair than for the other pair.  Hence, either the triangular, or the sine curve, initial deflection always produces the lowest fundamental frequency, while the parabolic initial deflection always produces the highest fundamental frequency.

3.  When the mass ratio exceeds 0.38, the triangular initial deflection yields the lowest fundamental frequency.  Otherwise, the sine curve initial deflection yields the lowest fundamental frequency.

4.  The second plot shows the ratio of the fundamental frequency of the string with a mass attached at its mid-length for mass ratios greater than 0.38 compared to the fundamental frequency of the string only.  The mass has a strong effect on the fundamental frequency - a mass approximately 1 times the mass of the string halves the fundamental frequency.  (When the mass is attached, the fundamental frequency is calculated for an initial triangular deflection, but for the string alone, it is calculated for a sinusoidal initial deflection.)

>	m := `mass ratio`*rho*l;

>	fr1 := simplify(fr(ans4,ans6));                           # sine/triangle

>	fr2 := simplify(fr(ans5,ans6));                           # parabola/triangle

>	fr3 := simplify(fr(ans4,ans5));                           # sine/parabola

>

f1 := plot(fr1,`mass ratio`=0..10,colour=RED,            # sine/triangle labeldirections=[HORIZONTAL,VERTICAL], labels=["Mass Ratio","Ratio of Fundamental Frequencies"],labelfont=[TIMES,ROMAN,12], title="Ratio of Fundamental Frequencies versus Mass Ratio\nfor pairs of different initial deflections", titlefont=[TIMES,ROMAN,14]):

>	f2 := plot(fr2,`mass ratio`=0..10,colour=BLUE):          # parabola/triangle

>	c := plot(1,`mass ratio`=0..10,linestyle=DOT,colour=BLACK):

>	t1 := plots[textplot]([7,1.09,"sine curve/triangle"],font=[TIMES,ITALIC,12]):

>	t2 := plots[textplot]([7,1.13,"parabola/triangle"],font=[TIMES,ITALIC,12]):

>	plots[display](f1,f2,c,t1,t2);

 The ratio of fundamental frequencies for the sine curve and triangular initial deflection pair is unity in the plot above when the mass ratio is given by

>	fsolve(fr1=1,{`mass ratio`});

 Comparing the fundamental frequency of the string with mass attached to that of the string only for mass ratios greater than 0.38,

>	fr4 := simplify(fr(ans6,ans1),symbolic);                 # mass attached/string only

>

plot(fr4,`mass ratio`=0.38..10,xtickmarks=10,labeldirections=[HORIZONTAL,VERTICAL], labels=["Mass Ratio","Ratio of Fundamental Frequencies"],labelfont=[TIMES,ROMAN,12], title="Ratio of Fundamental Frequencies versus Mass Ratio\nfor String with Mass Attached compared to String Only", titlefont=[TIMES,ROMAN,14]);

>

Observations

1.  The fundamental frequencies of vibration obtained in the first example for three different initial deflections were all within 11% of each other.  That for the sine curve was least and the same as the "exact" value obtained by solving the one-dimensional wave equation for a vibrating string, while that for the parabola was within 0.7% of it.  This illustrates not only the first part of Lord Rayleigh's principle, but also the second - namely that the closer the deflection chosen is to reality, the closer the calculated frequency is to reality.

2.  In the second example, when the ratio of the mass to that of the string exceeded 0.38, a triangular initial deflection produced the smallest fundamental frequency and the sine curve produced the next smallest.  Thus the best approximation to the true fundamental frequency depends on whether the mass ratio exceeds 0.38.

3.  The term initial deflection has been used in this worksheet to emphasize that this deflection does not persist.  During the vibration the deflection would very rapidly assume the shape that produces the lowest fundamental frequency - in accordance with Lord Rayleigh's principle.  Thus in the first example, the shape of the vibrating string would be sinusoidal, while in the second it would be triangular; or sinusoidal if the mass ratio was equal to, or less than, 0.38.  This accords with the intuitive notion that a large mass would pull the two halves of a light, elastic string out straight, while a very small mass would have little influence on the vibration, which would resemble that of the string alone.

4.  The ease with which solutions can be obtained by using Lord Rayleigh's principle is clear from the two examples above.  Although these are examples of continuous systems, the same ease of solution is found with discrete systems.

5.  Maple's symbolic algebra with its inert functions is ideal for showing students the steps for finding the fundamental frequency of a vibration using Lord Rayleigh's principle

Disclaimer:  While every effort has been made to validate the solutions in this worksheet, Waterloo Maple Inc. and the contributors are not responsible for any errors contained and are not liable for any damages resulting from the use of this material.