La Fibre Optique Multimode ? Gradient d'Indice
The Multimode Graded-Index Optical Fiber 

par le Professeur El Mahdi Assaid,
Laboratoire d'Electronique et Optique des Nanostructures de Semi-conducteurs (LEONS)
D?partement de Physique, Facult? des Sciences, Universit? Chouaib Doukkali ? El Jadida
Royaume du Maroc 

eassaid@yahoo.fr, ? 2006 El Mahdi Assaid 

Resume 

RESUME : Cette feuille pr?sente les capacit?s de Maple dans la r?solution d'un syst?me d'?quations diff?rentielles non lin?aires r?gissant la propagation de la lumi?re dans une fibre optique multimode ? gradient d'indice. Elle pr?sente aussi les possibilit?s offertes par Maple dans la composition des solutions et le trac? d'une courbe ? trois dimensions repr?sentant le trajet de la lumi?re dans le coeur de la fibre. 

SUJETS : Optique, Opto?lectronique et T?l?communications. 

 

ABSTRACT: This worksheet presents a demonstration of Maple's capabilities in the resolution of non-linear differential equations system governing the propagation of light in multimode graded-index optical fiber. It also presents the possibilities given by Maple in the composition of the solutions and the plot of a three dimensional curve representing the light's route in the fiber's core. 

SUBJECTS: Optics, Optoelectronics and Telecommunications. 

 

 

Introduction 

De nos jours, la fibre optique a tiss? sa toile autour du globe aux sens propre et figur? : 

i) Dans le domaine des t?l?communications, la fibre optique monomode sert comme support de transmission dans les r?seaux intercontinentaux, caract?ris?s par un haut d?bit et une longue distance. La fibre optique multimode est utilis?e pour le transfert d'informations dans les r?seaux locaux, caract?ris?s par un faible d?bit et une courte distance. 

ii) Nous retrouvons la fibre optique en chirurgie o? elle est utilis?e pour guider un faisceau laser dans le but de pulv?riser un calcul, d?couper une tumeur ou r?parer un r?tine. 

iii) Nous la retrouvons aussi en endoscopie o? elle est utilis?e pour ?clairer l'int?rieur du corps humain et transmettre les images jusqu'au m?decin. 

La fibre optique est aussi pr?sente dans un bon nombre de montages optiques. Son utilisation est appel?e ? connaitre un tr?s grand essor dans les ann?es ? venir. 

Dans cette feuille, nous allons ?tudier la propagation de la lumi?re dans une fibre optique ? gradient d'indice.  

 

EQUATION ICONALE 

 

Dans un milieu transparent, l'indice de r?fraction en un point de la trajectoire d'un rayon lumineux, est ?gal ? la norme du vecteur gradient de la fonction chemin optique au m?me point : 

 

 

 

est le vecteur unitaire tangent ? la trajectoire du rayon lumineux au point . 

 

LOI FONDAMENTALE DE L'OPTIQUE GEOMETRIQUE 

 

Dans un milieu transparent, la variation ?l?mentaire du vecteur en fonction de celle de l'abscisse curviligne en un point de la trajectoire d'un rayon lumineux, est ?gale au vecteur gradient de la fonction indice de r?fraction au m?me point : 

 

 

 

Le vecteur unitaire tangent ? la trajectoire du rayon lumineux au point a pour expression : 

 

est la variation ?l?mentaire du vecteur position. est la variation ?l?mentaire de la coordonn?e curviligne.   

Profile De L'Indice De Refraction Dans La Fibre A Gradient D'Indice 

>	restart:with(plots):Digits:=16:

 

FONCTION INDICE DE REFRACTION DANS LE COEUR 

et sont deux coordonn?es transversales. est la coordonn?e selon l'axe de la fibre.    

>	ncoeur:=(n1,Delta,a,alpha)->n1*(1-2*Delta*(abs(x)/a)^alpha)^(1/2);

 

(3.1)

 

CARACTERISTIQUES GEOMETRIQUES DE LA FIBRE 

est le rayon du coeur de la fibre. 

est le rayon de gaine de la fibre. 

>	a:=25*1E-6;b:=60*1E-6;

 

 

(3.2)

 

VARIATION DE L'INDICE DE REFRACTION DANS LE COEUR DE LA FIBRE 

est l'indice de r?fraction sur l'axe de la fibre.  

est l'indice de r?fraction ? la jonction entre le coeur et la gaine de la fibre.  

 

est l'exposant du profil d'indice. vaut 1 pour un profil triangulaire, 2 pour un profil parabolique et l' pour un profil carr?. 

>	n1:=1.5;n2:=1.485;Delta:=(n1-n2)/n1;alpha:=2;

 

 

 

 

(3.3)

 

>	plot(ncoeur(n1,Delta,a,alpha),x=-a..a);

 

 

>	alpha:='alpha';

 

(3.4)

 

PROFILS DE L'INDICE DE REFRACTION DANS LE COEUR DE LA FIBRE EN FONCTION DE LA COORDONNEE TRANSVERSALE POUR DIFFERENTES VALEURS DE  

>	plot({seq(ncoeur(n1,Delta,a,alpha), alpha=1..6)},x=-a..a,tickmarks=[5,5],title="Profils du gradient d'indice dans le coeur de la fibre");Fg:=%:

 

 

PROFIL DE L'INDICE DE REFRACTION DANS TOUTE LA FIBRE EN FONCTION DE LA COORDONNEE TRANSVERSALE POUR DIFFERENTES VALEURS DE  

>	nfibre:=piecewise( abs(x)>=b , 1 , abs(x) >= a , 1.485 , abs(x)<=a , n1*(1-2*Delta*(abs(x)/a)^alpha)^(1/2) );

 

(3.5)

 

>	plot({seq(nfibre,alpha=1..6)},x=-b..b,n=1.45..1.5,tickmarks=[5,5],title="profils du gradient d'indice dans toute la fibre");Fg:=%:

 

 

CAS LIMITE CORRESPONDANT A : LA FIBRE A SAUT D'INDICE 

>	nsaut:=x->if abs(x) < a then n1 else if abs(x)<b then 1.485 else 1 fi fi;

 

(3.6)

 

>	plot(nsaut,-b..b,n=1.45..1.5,tickmarks=[5,5],title="profil du saut d'indice");Fs:=%:

 

 

COMPARAISON ENTRE LE SAUT D'INDICE ET LE GRADIENT D'INDICE 

>	display({Fg,Fs},title="Profils gradients d'indice et saut d'indice");

 

 

Resolution Du Systeme D'Equations Regissant La Propagation D'Un Rayon Lumineux Dans Le Coeur De La Fibre. Cas Des Rayons Contenus Dans Un Plan Meridien 

En projettant la relation fondamentale de l'optique g?ometrique sur les trois vecteurs unitaires () de la base des coordonn?es cylindriques, et en tenant compte des conditions initiales ? l'entr?e de la fibre nous obtenons : 

(1)   

(2) 

(3)           

Nous consid?rons que le rayon lumineux entre dans la fibre par le point O de coordonn?es () telles que et . L'?quation 2 devient : 

  

Il en r?sulte que . Le rayon se propageant dans la fibre reste dans un plan m?ridien.   

>	restart:with(plots):

 

>	ncoeur:=n1*(1-2*Delta*(rho/a)^alpha)^(1/2);

 

(4.1)

 

>	diff(ncoeur,rho);

 

(4.2)

 

>	alias(rho=rho(s)): alias(z=z(s)): alias(rho0=rho(0)): alias(rhop0=D(rho)(0)): alias(z0=z(0)):

 

L'?quation 1 s'?crit : 

>	eq1:=-n1/(1-2*Delta*(rho/a)^alpha)^(1/2)*Delta*(rho/a)^alpha*alpha/rho*diff(rho,s)*diff(rho,s)+n1*sqrt(1-2*Delta*(rho/a)^alpha)*diff(rho,s,s)+n1/(1-2*Delta*(rho/a)^alpha)^(1/2)*Delta*(rho/a)^alpha*alpha/rho=0;

 

(4.3)

 

L'?quation 3 s'?crit : 

>	eq3:=n1*sqrt(1-2*Delta*(rho/a)^alpha)*diff(z,s)=n0*zp0;

 

(4.4)

 

CARACTERISTIQUES GEOMETRIQUE ET OPTIQUES DE LA FIBRE 

>	a:=25*1E-6;Delta:=0.01;alpha:=2;n1:=1.5;

 

 

 

 

(4.5)

 

CONDITIONS INITIALES 

L'indice de r?fraction au point est ?gal ? . Le vecteur unitaire tengent au rayon lumineux au point O a pour composantes telles que , et =. 

La valeur 0.1415 est une valeur limite au del? de laquelle le rayon lumineux n'est plus guid? dans le coeur de la fibre, mais le quitte lorsqu'il parvient ? la jonction entre le coeur et la gaine. 

>	n0:=n1;zp0:=sqrt(1-0.1415^2);

 

 

(4.6)

 

>

eq1;

 

(4.7)

 

>

eq3;

 

(4.8)

 

>	sys1:=(eq1,eq3);

 

(4.9)

 

>	fcns1 := {rho,z};

 

(4.10)

 

>	p1:= dsolve({eq1,eq3,rho0=0,rhop0=0.1415,z0=0},fcns1,numeric,stiff=true,abserr=1e-16,range=0..0.02);

 

(4.11)

 

Dans la figure suivante, nous donnons les variations de la solution en fonction de s. La ligne verte d?signe la jonction entre le coeur et la gaine de la fibre.  

>	odeplot(p1, [[s,rho],[s,a]],0..0.02,refine=2);F1:=%:

 

 

Pour montrer que la solution est bien p?riodique, nous repr?sentons dans la figure suivante en fonction de . Le r?sultat est une courbe ferm?e qui rappelle la courbe de Lissajous.  

>	odeplot(p1, [rho,diff(rho,s)], 0..0.02,refine=2);

 

 

Pour tester la validit? de l'approximation de gauss ou approximation de l'optique paraxiale qui consiste ? approcher par , nous tra?ons dans la figure suivante les variations de en fonction de . 

>	odeplot(p1, [s,z], 0..0.02,refine=2);

 

 

La figure pr?c?dente laisse penser que . En r?alit?, cette ?galit? n'est rigoureusement exacte que lorsque le rayon incident entre dans la fibre en faisant un angle nul avec l'axe. Pour pouvoir s'en rendre compte, nous repr?sentons dans la figure suivante les variations de en fonction de et dans la figure qui la suit nous comparons avec .  

>	odeplot(p1, [z,rho], 0..0.02,refine=2,color=blue);F2:=%:

 

 

>	display({F1,F2});

 

 

 

Resolution Du Systeme D'Equations Regissant La Propagation D'Un Rayon Lumineux Dans Le Coeur De La Fibre. Cas Des Rayons Helicoidaux 

>	restart:with(plots):

 

>	ncoeur:=n1*(1-2*Delta*(rho/a)^alpha)^(1/2);

 

(5.1)

 

>	diff(ncoeur,rho);

 

(5.2)

 

>	alias(rho=rho(s)): alias(phi=phi(s)): alias(z=z(s)): alias(rho0=rho(0)): alias(phi0=phi(0)): alias(rhop0=D(rho)(0)): alias(z0=z(0)):

 

L'?quation 1 s'?crit : 

>	eq1:=-n1/(1-2*Delta*(rho/a)^alpha)^(1/2)*Delta*(rho/a)^alpha*alpha/rho*diff(rho,s)*diff(rho,s)+n1*sqrt(1-2*Delta*(rho/a)^alpha)*diff(rho,s,s)-n1*sqrt(1-2*Delta*(rho/a)^alpha)*rho*diff(phi,s)*diff(phi,s)+n1/(1-2*Delta*(rho/a)^alpha)^(1/2)*Delta*(rho/a)^alpha*alpha/rho=0;

 

(5.3)

 

L'?quation 2 s'?crit : 

>	eq2:=n1*sqrt(1-2*Delta*(rho/a)^alpha)*rho*rho*diff(phi,s)=n0*rho02*phip0;

 

(5.4)

 

L'?quation 3 s'?crit : 

>	eq3:=n1*sqrt(1-2*Delta*(rho/a)^alpha)*diff(z,s)=n0*zp0;

 

(5.5)

 

CARACTERISTIQUES GEOMETRIQUE ET OPTIQUES DE LA FIBRE 

>	a:=25*1E-6;b:=60*1E-6;Delta:=0.01;alpha:=2;n1:=1.5;

 

 

 

 

 

(5.6)

 

CONDITIONS INITIALES 

Nous consid?rons que le rayon lumineux entre dans la fibre par le point de coordonn?es () telles que et . 

L'indice de r?fraction au point est ?gal ? . Le vecteur unitaire tengent au rayon lumineux au point a pour composantes : telles que , et = 

La valeur 0.1415 est une valeur limite au del? de laquelle le rayon lumineux n'est plus guid? dans le coeur de la fibre, mais le quitte lorsqu'il parvient ? la jonction entre le coeur et la gaine. 

>	n0:=n1*(1-2*Delta*((a/2)/a)^alpha)^(1/2);rho02:=(a/2)*(a/2);phip0:=0.1415/(a/2);zp0:=sqrt(1-0.1415^2);

 

 

 

 

(5.7)

 

>

eq1;

 

(5.8)

 

>

eq2;

 

(5.9)

 

>

eq3;

 

(5.10)

 

>	sys1:=(eq1,eq2,eq3);

 

(5.11)

 

>	fcns1 := {rho,phi,z};

 

(5.12)

 

>	p1:= dsolve({eq1,eq2,eq3,rho0=a/2,rhop0=0,phi0=Pi/3,z0=0},fcns1,numeric,stiff=true,abserr=1e-16,range=0..0.006);

 

(5.13)

 

Dans la figure suivante, nous donnons les variations de la solution en fonction de s. La ligne verte indique l'interface entre le coeur et la gaine de la fibre. Nous pouvons remarquer que le rayon lumineux est guid? dans le coeur de la fibre.    

>	odeplot(p1, [[s,rho],[s,a]], 0..0.006,refine=2);F1:=%:

 

 

Dans la figure suivante, nous repr?sentons en fonction de . Le r?sultat est une courbe ferm?e qui montre bien que est p?riodique. Cependant, la courbe est assym?trique car en coordonn?es cylindriques, est toujours positif.  

>	odeplot(p1, [rho,diff(rho,s)], 0..0.006,refine=2);

 

 

Dans la figure suivante, nous repr?sentons les variations de en fonction de . La figure illustre bien le fait que le front d'onde du rayon incident d?crit une trajectoire h?lico?dale.   

>	odeplot(p1, [s,phi], 0..0.006,refine=2);

 

 

Dans le but de tester la validit? de l'approximation de gauss ou approximation de l'optique paraxiale, nous tra?ons dans la figure suivante les variations de en fonction de . Contrairement ? la partie pr?c?dente o? la diff?rence entre et devient visible losque le front d'onde a parcouru quelques centim?tres, ici elle ?vidente d?s les premiers millim?tres.  

>	odeplot(p1,[[s,z],[s,s]], 0..0.006,refine=2);

 

 

Dans la figure suivante, nous tra?ons les variations de en fonction de et dans la figure qui la suit nous comparons avec . Nous pouvons dire que devient differente de d?s le troisi?me millim?tre.  

>	odeplot(p1, [z,rho], 0..0.006,refine=2,color=blue);F2:=%:

 

 

>	display({F1,F2});

 

 

Dans la figure suivante, nous reportons la trajectoire du rayon incident dans le coeur de la fibre. 

>	odeplot(p1,[rho*cos(phi),rho*sin(phi),z],0..0.006,color=red,refine=2,axes=none,orientation=[45,45]);A:=%:

 

 

Dans la figure suivante, nous repr?sentons la trace de la trajectoire du rayon lumineux dans le plan orthogonal ? l'axe de la fibre. 

>	odeplot(p1,[rho*cos(phi),rho*sin(phi),s],0..0.006,color=red,refine=2,axes=boxed,orientation=[0,0]);

 

 

Dans la figure suivante, nous repr?sentons la trace de la trajectoire du rayon lumineux dans le plan m?ridien de la fibre. 

>	odeplot(p1,[rho*cos(phi),rho*sin(phi),z],0..0.006,color=red,refine=2,axes=boxed,orientation=[0,90]);

 

 

>	with(plottools):

 

>	l := line([0,0,0], [0,0,0.006], color=black, linestyle=3):

 

>	plot3d(a,theta=3*Pi/4..7*Pi/4,h=0..0.006,grid=[12,8],coords=cylindrical,linestyle=DOT,color=white):coeur:=%:

 

>	plot3d(b,theta=Pi/2..2*Pi,h=0..0.006,grid=[16,8],coords=cylindrical,linestyle=DOT,color=white):gaine:=%:

 

>	display({A,coeur,gaine,l},axes=none,orientation=[45,65],title="Propagation d'un signal optique dans une fibre");figure:=%:

 

 

Conclusion 

L'utilisateur de la pr?sente feuille a la possibilit? d'effectuer les changements suivants : 

i) Changer les conditions initiales relatives ? l'entr?e du rayon incident dans la fibre. 

ii) Changer l'exposant du profil d'indice et regarder les changement qui interviennent au niveau de la trajectoire du rayon lumineux. 

L'utilisateur a aussi la possibilit? de faire les approximations suivantes dans l'?quation diff?rentielle radiale : 

i) N?gliger le terme quadratique et v?rifier que la solution num?rique reste presque la m?me. 

ii) D?crire le gradient d'indice dans le coeur de la fibre par la fonction et v?rifier que le changement au niveau de la solution num?rique est faible. 

 

 

Legal Notice: The copyright for this application is owned by the author(s). Neither Maplesoft nor the author are responsible for any errors contained within and are not liable for any damages resulting from the use of this material. This application is intended for non-commercial, non-profit use only. Contact the author for permission if you wish to use this application in for-profit activities.