La Fibre Optique ? Saut d'Indice 

The Step-Index Optical Fiber 

par le Professeur El Mahdi Assaid,  

Laboratoire d'Electronique et Optique des Nanostructures de Semi-conducteurs (LEONS) 

Groupe d'Electronique et Optique du Solide (GEOS) 

D?partement de Physique, Facult? des Sciences, Universit? Choua?b Doukkali ? El Jadida 

Royaume du Maroc 

eassaid@yahoo.fr, ? 2006 El Mahdi Assaid 

RESUME : Cette feuille pr?sente une d?monstration des capacit?s offertes par le logiciel de calcul symbolique Maple dans la r?solution d'?quations diff?rentielles r?gissant la propagation d'une onde ?lectromagn?tique dans une fibre optique ? saut d'indice dont le rayon du coeur est voisin de la longueur d'onde de la radiation incidente.  Elle pr?sente aussi les fonctionnalit?s graphiques ? deux et trois dimensions que Maple met ? la disposition de son utilisateur ce qui permet de : 

i) Acc?der directement aux solutions de l'?quation aux valeurs propres. 

ii) V?rifier ais?ment les relations de continuit? des composantes tengentielles des champs ?lectrique E et magn?tique H ? l'interface entre le coeur et la gaine de la fibre. 

iii) Repr?senter dans l'espace ? trois dimensions les champs des vecteurs E et H. 

vi) Repr?senter dans le plan transversal de la fibre la r?partition de l'intensit? lumineuse. 

SUJETS : Optique, Opto?lectronique, T?l?communications et Electromagn?tisme. 

MOTS CLES : Fibre optique, Saut d'indice, Mode guid?, Mode transverse ?lectrique. 

ABSTRACT : This worksheet presents a demonstration of Maple software's capabilities in the resolution of differential equations governing the propagation of an electromagnetic wave in a step-index optical fiber with a core radius of the order of magnitude of the incident radiation wavelength. It also presents the two and three dimensions graphical functionalities given by Maple which allows : 

i) To access directly to the eigenvalue equation solutions. 

ii) To check easily the continuity conditions of the electric E and magnetic H tangent components at the core-cladding boundary. 

iii) To show in the three dimensions space the E and H vector fields. 

iv) To show in the fiber transverse plane the light intensity distribution. 

SUBJECTS : Optics, Optoelectronics, Telecommunications and Electromagnetism. 

KEYWORDS : Optical fiber, Step-index, Guided mode, Transverse electric mode.  

INTRODUCTION 

Le probl?me de la propagation de la lumi?re dans une fibre optique peut ?tre trait? par deux approches diff?rentes : 

1) La premi?re approche est l'approche g?om?trique qui consid?re que la lumi?re est compos?e d'un ensemble de rayons lumineux, elle est utilis?e lorsque le rayon du coeur de la fibre est grand devant la longueur d'onde de la radiation incidente. Cette approche est expos?e dans la feuille intitul?e [1] : "Fibre Optique Multimode A Gradient D'Indice". 

Cette feuille est disponible ? l'adresse ?lectronique : 

 

http://www.maplesoft.com/applications/app_center_view.aspx?AID=2022 

 

2) La deuxi?me approche est l'approche ondulatoire qui consid?re la lumi?re comme une onde ?lectromagn?tique, elle est utilis?e lorsque le rayon de la fibre est voisin de la longueur d'onde de la radiation incidente. Cette approche est expos?e dans la pr?sente feuille. 

EQUATIONS DE L'ONDE ELECTROMAGNETIQUE 

Dans un milieu di?lectrique et non magn?tique, les ?quations de Maxwell s'?crivent [2] : 

(1),     (2), 

(3),          (4). 

o? les vecteurs champ ?lectrique et d?placement ?lectrique sont li?s par la relation [2] : (5), 

et les vecteurs champ magn?tique et induction magn?tique sont li?s par la relation [2] : (6). 

est le vecteur densit? de courant, il est exprim? par la relation [2] :   (7). 

Dans le cas o? il n'y a pas de courant ?lectrique, . 

Dans le cas o? il n'y a pas de charges volumiques, . 

Les ?quations de Maxwell peuvent alors se r??crire [2] : 

(8),     (9), 

(10),         (11). 

En appliquant l'op?rateur ? l'?quation (1), nous obtenons : 

(12). 

Sachant que : , l'?quation (12) devient : 

(13).   

De la m?me mani?re, nous pouvons montrer que : 

(14). 

Les ?quations diff?rentielles (13) et (14) constituent les ?quations de l'onde ?lectromagn?tique dans un milieu di?lectrique et non magn?tique.   

>

restart:

 

>	with(PDEtools):

 

Nous d?finissons le laplacien en coordonn?es cart?siennes :  

>	L := f -> diff(f,X$2) +diff(f,Y$2)+diff(f,Z$2);

 

(2.1)

 

Nous transformons ce Laplacien en coordonn?es cylindriques : 

>	tr := {X = r*cos(phi), Y = r*sin(phi), Z=z};

 

(2.2)

 

>	`L'` := dchange(tr,L,simplify);

 

(2.3)

 

Nous ?crivons les ?quations de propagation pour les champ ?lectrique E et magn?tique H en tenant compte du fait que [15] : 

>	pde1:=`L'`(E(r,phi,z,t))-(k^2*n^2/omega^2)*diff(diff(E(r,phi,z,t),t),t)=0;

 

(2.4)

 

>	pde2:=`L'`(H(r,phi,z,t))-(k^2*n^2/omega^2)*diff(diff(H(r,phi,z,t),t),t)=0;

 

(2.5)

 

est le module du vecteur d'onde de la radiation incidente. est l'indice de r?fraction du milieu h?te. est la pulsation de l'onde incidente.       

SEPARATION DES VARIABLES 

Nous projettons l'?quation de propagation pour le champ ?lectrique E sur l'axe de la fibre. Puis, nous cherchons une solution ? cette ?quation, s?parable dans la base des coordonn?es cylindriques (), ayant : 

1) Comme direction de propagation l'axe de la fibre, 

2) Pour sens de propagation celui dirig? vers les z positifs, 

3) Une d?pendance harmonique en fonction de la phase ()  traduite par le terme . 

Dans ces conditions, la solution de l'?quation de propagation pour le champ ?lectrique E s'?crit : [16].  

>	Struc := pdsolve(pde1,HINT = R(r)*Phi(phi)*exp(I*(beta*z-omega*t)));

 

(3.1)

 

La fonction doit pr?senter la sym?trie de r?volution par rapport ? l'axe , c'est ? dire que doit ?tre ?gale ? . Pour cel?, la constante doit ?tre positive. Nous posons : _ [17].      

>	ed0:=diff(Phi(phi),`$`(phi,2)) = -Phi(phi)*l^2;

 

(3.2)

 

>	dsolve(ed0);

 

(3.3)

 

Nous rempla?ons la fonction par dans l'expression de en vue de d?terminer l'?quation diff?rentielle radiale : 

>	Struc := pdsolve(pde1,HINT = R(r)*exp(I*l*phi)*exp(I*(beta*z-omega*t)));

 

(3.4)

 

PROFIL DU SAUT D'INDICE DANS LA FIBRE 

Dans une fibre ? saut d'indice, l'indice de r?fraction dans le coeur de la fibre est diff?rent de l'indice de r?fraction dans la gaine de la fibre. Pour repr?senter le profil de l'indice de r?fraction en fonction de la coordonn?e transversale , nous prenons :  

>	n1:=1.451;n2:=1.45;a:=.1891151151e-4;

 

(4.1)

 

(4.1)

 

(4.1)

 

>	nsaut:=x->if abs(x) < a then n1 else n2 fi;

 

(4.2)

 

>	plot(nsaut,-2*a..2*a,title="profil du saut d'indice");

 

 

RESOLUTION DE L'EQUATION RADIALE DANS LE COEUR 

LE RAYON DU COEUR DE LA FIBRE EST EGAL A . L'INDICE DE REFRACTION DANS LE COEUR DE LA FIBRE EST EGAL A .   

DANS LE COEUR DE LA FIBRE, LE CHAMP ELECTRIQUE DOIT ETRE OSCILLANT. 

CE QUI VEUT DIRE QUE : . NOUS POSONS [18].  

>

restart;

 

>	ed1:=diff(R(r),`$`(r,2)) = (R(r)*l^2-diff(R(r),r)*r-(u^2/a^2)*R(r)*r^2)/r^2;

 

(5.1)

 

>	dsolve(ed1);

 

(5.2)

 

Lorsque tend vers , la fonction reste finie, la fonction diverge. peut alors s'?crire : 

>	R(r):=_C1*BesselJ(l,u*r/a);

 

(5.3)

 

RESOLUTION DE L'EQUATION RADIALE DANS LA GAINE 

LE RAYON DE GAINE DE LA FIBRE EST INFINI. L'INDICE DE REFRACTION DANS LA GAINE DE LA FIBRE EST EGAL A .   

DANS LA GAINE DE LA FIBRE, LE CHAMP ELECTRIQUE DOIT ETRE EVANESCENT. 

CE QUI VEUT DIRE : . NOUS POSONS [19].  

>	R(r):='R(r)';

 

(6.1)

 

>	ed2:=diff(R(r),`$`(r,2)) = (R(r)*l^2-diff(R(r),r)*r+R(r)*(w^2/a^2)*r^2)/r^2;

 

(6.2)

 

>	dsolve(ed2);

 

(6.3)

 

Lorsque tend vers l', la fonction tend vers , la fonction tend vers l'infini. peut alors s'?crire : 

>	R(r):=_C2*BesselK(l,w*r/a);

 

(6.4)

 

COMPOSANTES SELON DES CHAMPS E ET H  

>

restart;

 

Avec un calcul similaire au pr?c?dent, nous pouvons d?terminer les composantes selon du champ magn?tique H dans le coeur et dans la gaine de la fibre. En conclusion, les composantes selon des champs ?lectrique E et magn?tique H s'?crivent : 

1) Dans le coeur de la fibre : 

>	E[z,1]:=(r,phi,l,u,a,A)->A*BesselJ(l,u*r/a)*sin(l*phi);

 

(7.1)

 

>	H[z,1]:=(r,phi,l,u,a,B)->B*BesselJ(l,u*r/a)*cos(l*phi);

 

(7.2)

 

 

2) Dans la gaine de la fibre : 

>	E[z,2]:=(r,phi,l,w,a,C)->C*BesselK(l,w*r/a)*sin(l*phi);

 

(7.3)

 

>	H[z,2]:=(r,phi,l,w,a,F)->F*BesselK(l,w*r/a)*cos(l*phi);

 

(7.4)

 

A, B, C et F sont des r??ls ? d?terminer. 

COMPSANTES SELON ET DES CHAMPS E ET H 

En combinant les deux pr?mi?res ?quations de Maxwell, nous pouvons montrer que les composantes radiales et angulaires des champs ?l?ctrique E et magn?tique H s'?crivent : 

1) Dans le coeur de la fibre : 

[20] 

[21] 

[22] 

[23] 

2) Dans la gaine de la fibre : 

[24] 

[25] 

 

[26] 

 

[27]  

 

A partir de cet instant, nous affectons ? l'indice et ? l'indice .     

>	Er1:=simplify(-I*a^2/u^2*(beta[z]*diff(E[z,1](r,phi,l,u,a,A),r)+omega*mu[0]*1/r*diff(H[z,1](r,phi,l,u,a,B),phi)));

 

(8.1)

 

>	E[r,1]:=unapply(Er1,(r,phi,l,u,a,A,B));

 

(8.2)

 

>	Ephi1:=simplify(-I*a^2/u^2*(beta[z]*1/r*diff(E[z,1](r,phi,l,u,a,A),phi)-omega*mu[0]*diff(H[z,1](r,phi,l,u,a,B),r)));

 

(8.3)

 

>	E[phi,1]:=unapply(Ephi1,(r,phi,l,u,a,A,B));

 

(8.4)

 

>	Hr1:=simplify(-I*a^2/u^2*(beta[z]*diff(H[z,1](r,phi,l,u,a,B),r)-omega*epsilon[0]*n1^2*1/r*diff(E[z,1](r,phi,l,u,a,A),phi)));

 

(8.5)

 

>	H[r,1]:=unapply(Hr1,(r,phi,l,u,a,A,B));

 

(8.6)

 

>	Hphi1:=simplify(-I*a^2/u^2*(beta[z]*1/r*diff(H[z,1](r,phi,l,u,a,B),phi)+omega*epsilon[0]*n1^2*diff(E[z,1](r,phi,l,u,a,A),r)));

 

(8.7)

 

>	H[phi,1]:=unapply(Hphi1,(r,phi,l,u,a,A,B));

 

(8.8)

 

>	Er2:=simplify(I*a^2/w^2*(beta[z]*diff(E[z,2](r,phi,l,w,a,C),r)+omega*mu[0]*1/r*diff(H[z,2](r,phi,l,w,a,F),phi)));

 

(8.9)

 

>	E[r,2]:=unapply(Er2,(r,phi,l,w,a,C,F));

 

(8.10)

 

>	Ephi2:=simplify(I*a^2/w^2*(beta[z]*1/r*diff(E[z,2](r,phi,l,w,a,C),phi)-omega*mu[0]*diff(H[z,2](r,phi,l,w,a,F),r)));

 

(8.11)

 

>	E[phi,2]:=unapply(Ephi2,(r,phi,l,w,a,C,F));

 

(8.12)

 

>	Hr2:=simplify(I*a^2/w^2*(beta[z]*diff(H[z,2](r,phi,l,w,a,F),r)-omega*epsilon[0]*n2^2*1/r*diff(E[z,2](r,phi,l,w,a,C),phi)));

 

(8.13)

 

>	H[r,2]:=unapply(Hr2,(r,phi,l,w,a,C,F));

 

(8.14)

 

>	Hphi2:=simplify(I*a^2/w^2*(beta[z]*1/r*diff(H[z,2](r,phi,l,w,a,F),phi)+omega*epsilon[0]*n2^2*diff(E[z,2](r,phi,l,w,a,C),r)));

 

(8.15)

 

>	H[phi,2]:=unapply(Hphi2,(r,phi,l,w,a,C,F));

 

(8.16)

 

EQUATION AUX VALEURS PROPRES 

En appliquant les relations de continuit? des composantes tangentielles des champs ?lectrique E et magn?tique H ? la jonction entre le coeur et la gaine, nous  montrons que :   

>	F=B*BesselJ(l,u)/BesselK(l,w);

 

(9.1)

 

>	C=A*BesselJ(l,u)/BesselK(l,w);

 

(9.2)

 

Ces relations de continuit? aboutissent aussi ? un syst?me de 4 ?quations ? 4 inconnues : A,B,C et F dont le d?terminant doit ?tre nul. En ?valuant le d?terminant nous conduisons ? l'?quation aux valeurs propres : 

 

  =     [28]      

 

Dans le cadre de l'approximation du faible guidage qui stipule que , l'?quation aux valeurs propres devient : 

 

 = [29] 

MODES TRANSVERSES ELECTRIQUES 

Les modes transverses ?lectriques sont caract?ris?s par : 

1) Un nombre de mode nul. 

2) Un champ ?lectrique transversal par rapport ? la direction de propagation. C'est ? dire que A = C = 0. 

L'?quation aux valeurs propres relative aux modes transverses ?lectriques s'?crit : 

[30] 

Nous pouvons d?finir la fr?quence normalis?e du guide d'ondes de la mani?re suivante : . 

En tenant compte des expressions de et de , la fr?quence normalis?e peut aussi admettre comme expression : . 

La fr?quence normalis?e est une grandeur physique qui d?pend de la nature du guide par le biais de , et et de la nature de l'onde incidente par le biais de . 

>	with(plots):

 

>

u:='u';

 

(10.1)

 

>

w:='w';

 

(10.2)

 

>

V:='V';

 

(10.3)

 

Le membre gauche de l'?quation [30] s'?crit : 

>	fJ:=BesselJ(1,u)/BesselJ(0,u);

 

(10.4)

 

Le membre droit de l'?quation [30] s'?crit : 

>	fK:=-u/sqrt(V^2-u^2)*BesselK(1,sqrt(V^2-u^2))/BesselK(0,sqrt(V^2-u^2));

 

(10.5)

 

Par la suite, nous travaillerons avec une fr?quence normalis?e ?gale ? 8.  

>	fK0:=subs(V=8,fK);

 

(10.6)

 

>	plot(fJ,u=0..12,y=-5..5):G:=%:

 

>	plot(fK0,u=0..8,y=-5..0,color=blue):H:=%:

 

>	display({G,H});

 

 

NOUS NOUS INTERESSONS AU MODE . NOUS CHERCHONS DONC LA DEUXIEME SOLUTION DE L'EQUATION AUX VALEURS PROPRES [30] : 

>	fsolve(fJ=fK0,u=5.520..8);

 

(10.7)

 

CARACTERISTIQUES DU MODE PROPAGE 

>

l:=0;

 

(10.8)

 

>	V:=8;u:=6.142539763;w:=sqrt(V^2-u^2);

 

(10.9)

 

(10.9)

 

(10.9)

 

>	A:=0;C:=0;B:=1;F:=B*BesselJ(l,u)/BesselK(l,w);

 

(10.10)

 

(10.10)

 

(10.10)

 

(10.10)

 

CARACTERISTIQUES DE L'ONDE INCIDENTE AVANT L'ENTREE DANS LE GUIDE 

>	lambda[0]:=800*10^(-9);k[0]:=evalf(2*Pi/lambda[0]);omega:=evalf(2*Pi*300000000/lambda[0]);T:=evalf(2*Pi/omega);

 

(10.11)

 

(10.11)

 

(10.11)

 

(10.11)

 

CARACTERISTIQUES DIELECTRIQUES ET MAGNETIQUES DU GUIDE D'ONDE 

>	mu[0]:=evalf(4*Pi*0.0000001);n1:=1.451;n2:=1.45;

 

(10.12)

 

(10.12)

 

(10.12)

 

CARACTERISTIQUE GEOMETRIQUE DU GUIDE D'ONDE  

>	a:=evalf(V/k[0]/sqrt(n1^2-n2^2));

 

(10.13)

 

CARACTERISTIQUES DE L'ONDE INCIDENTE APRES L'ENTREE DANS LE GUIDE 

>	beta[z]:=sqrt(-u^2/a^2+n1^2*k[0]^2);lambda[g]:=evalf(2*Pi/beta[z]);beta[t]:=sqrt(n1^2*k[0]^2-beta[z]^2);neff:=beta[z]/k[0];

 

(10.14)

 

(10.14)

 

(10.14)

 

(10.14)

 

>

beta[z];

 

(10.15)

 

REPRESENTATION DE L'INDICE EFFECTIF DU MODE PAR RAPPORT AU PROFIL DU SAUT D'INDICE  

>	nsaut:=x->if abs(x) < a then n1 else n2 fi;

 

(10.16)

 

>	plot([nsaut,neff],-2*a..2*a,title="Indice effectif \n par rapport au profil du saut d'indice");

 

 

REPRESENTATIONS GRAPHIQUES DU MODE  

>

 

FONCTIONS CORRESPONDANT AUX COMPOSANTES DES CHAMPS ELECTRIQUE E ET MAGNETIQUE H DANS LE COEUR DE LA FIBRE  

>	E[r,1](r,phi,l,u,a,A,B);

 

(11.1)

 

>	E[phi,1](r,phi,l,u,a,A,B);

 

(11.2)

 

>	E[z,1](r,phi,l,u,a,A);

 

(11.3)

 

>	H[r,1](r,phi,l,u,a,A,B);

 

(11.4)

 

>	H[phi,1](r,phi,l,u,a,A,B);

 

(11.5)

 

>	H[z,1](r,phi,l,u,a,B);

 

(11.6)

 

FONCTIONS CORRESPONDANT AUX COMPOSANTES DES CHAMPS ELECTRIQUE E ET MAGNETIQUE H DANS LA GAINE DE LA FIBRE  

>	E[r,2](r,phi,l,w,a,C,F);

 

(11.7)

 

>	E[phi,2](r,phi,l,w,a,C,F);

 

(11.8)

 

>	E[z,2](r,phi,l,w,a,C);

 

(11.9)

 

>	H[r,2](r,phi,l,w,a,C,F);

 

(11.10)

 

>	H[phi,2](r,phi,l,w,a,C,F);

 

(11.11)

 

>	H[z,2](r,phi,l,w,a,F);

 

(11.12)

 

EXPRESSIONS DES COMPOSANTES DES CHAMPS ELECTRIQUE E ET MAGNETIQUE H DANS LE COEUR DE LA FIBRE  

>

Er1;

 

(11.13)

 

>

Ephi1;

 

(11.14)

 

>	Ez1:=A*BesselJ(l,u*r/a)*sin(l*phi);

 

(11.15)

 

>

Hr1;

 

(11.16)

 

>

Hphi1;

 

(11.17)

 

>	Hz1:=B*BesselJ(l,u*r/a)*cos(l*phi);

 

(11.18)

 

EXPRESSIONS DES COMPOSANTES DES CHAMPS ELECTRIQUE E ET MAGNETIQUE H DANS LA GAINE DE LA FIBRE  

>

Er2;

 

(11.19)

 

>

Ephi2;

 

(11.20)

 

>	Ez2:=C*BesselK(l,w*r/a)*sin(l*phi);

 

(11.21)

 

>

Hr2;

 

(11.22)

 

>

Hphi2;

 

(11.23)

 

>	Hz2:=F*BesselK(l,w*r/a)*cos(l*phi);

 

(11.24)

 

CONTINUITE DE LA COMPOSANTE ANGULAIRE DU CHAMP ELECTRIQUE E  

Nous avons le choix d'utiliser la fonction champ ?lectrique transversal ou bien l'expression du champ ?lectrique transversal. 

>	plot([Im(E[phi,1](r,phi,l,u,a,A,B)),Im(E[phi,2](r,phi,l,w,a,C,F))],r=0..2*a,Ephi=-6000..6000,title="Composante angulaire du champ ?lectrique E\nMode TE[02]");

 

 

>	plot([Im(Ephi1),Im(Ephi2)],r=0..2*a,Ephi=-6000..6000,title="Composante angulaire du champ ?lectrique E\nMode TE[02]");

 

 

CONTINUITE DE LA COMPOSANTE RADIALE DU CHAMP MAGNETIQUE H 

>	plot([Im(Hr1),Im(Hr2)],r=0..2*a,Hr=-50..50,title="Composante radiale du champ magn?tique H\nMode TE[02]");

 

 

CONTINUITE DE LA COMPOSANTE LONGITUDINALE DU CHAMP MAGNETIQUE H 

>	plot([Hz1,Hz2],r=0..2*a,Hz=-10..10,title="Composante longitudinale du champ magn?tique H\nMode TE[02]");

 

 

REPRESENTATION DU CHAMP ELECTRIQUE E DANS LA FIBRE A L'INSTANT .  

>	fieldplot3d([0,Im(Ephi1*exp(I*beta[z]*z)),0],r=0..a,phi=0..2*Pi,z=0..lambda[g]/2,grid=[10,10,4],thickness=1,coords=cylindrical,color=blue,arrows=SLIM):E1_vec_field:=%:

 

>	fieldplot3d([0,Im(Ephi2*exp(I*beta[z]*z)),0],r=a..2*a,phi=0..2*Pi,z=0..lambda[g]/2,grid=[10,10,4],thickness=1,coords=cylindrical,color=green,arrows=SLIM):E2_vec_field:=%:

 

>	plot3d(a,phi=Pi/2..2*Pi,z=0..lambda[g]/2,grid=[10,4],coords=cylindrical,linestyle=DOT,color=white):coeur:=%:

 

>	display({E1_vec_field,E2_vec_field,coeur},axes=framed,orientation=[45,65],projection=1,title="Champ ?lectrique E dans la fibre\n? l'instant t = 0. Mode TE[02]");

 

 

REPRESENTATION DU CHAMP ELECTRIQUE E DANS LE PLAN TRANSVERSAL DE LA FIBRE A L'INSTANT .  

>	fieldplot3d([0,Im(Ephi1*exp(I*beta[z]*z)),0],r=0..a,phi=0..2*Pi,z=0..lambda[g]/2,grid=[12,12,2],thickness=0,coords=cylindrical, color=blue,arrows=SLIM,orientation=[0,0]):E1_tr_vec_field:=%:

 

>	fieldplot3d([0,Im(Ephi2*exp(I*beta[z]*z)),0],r=a..2*a,theta=0..2*Pi,z=0..lambda[g]/2,grid=[12,12,2],thickness=0,coords=cylindrical, color=green,arrows=SLIM,orientation=[0,0]):E2_tr_vec_field:=%:

 

>	plot3d(a,phi=0..2*Pi,z=0..lambda[g]/2,grid=[24,4],coords=cylindrical,linestyle=DOT,color=white):coeur1:=%:

 

>	display({E1_tr_vec_field,E2_tr_vec_field,coeur1},axes=boxed,title="Champ ?lectrique E dans le plan transversal de la fibre\n? l'instant t = 0. Mode TE[02]");

 

 

REPRESENTATION DU CHAMP MAGNETIQUE H DANS LA FIBRE A L'INSTANT .  

>	fieldplot3d([Im(Hr1*exp(I*beta[z]*z)),0,Im(Hz1*exp(I*beta[z]*z))],r=0..a,phi=0..2*Pi,z=0..lambda[g]/2,grid=[10,10,4],thickness=1,coords=cylindrical,color=blue,arrows=SLIM):H1_vec_field:=%:

 

>	fieldplot3d([Im(Hr2*exp(I*beta[z]*z)),0,Im(Hz2*exp(I*beta[z]*z))],r=a..2*a,phi=0..2*Pi,z=0..lambda[g]/2,grid=[10,10,4],thickness=1,coords=cylindrical,color=green,arrows=SLIM):H2_vec_field:=%:

 

>	plot3d(a,phi=Pi/2..2*Pi,z=0..lambda[g]/2,grid=[10,4],coords=cylindrical,linestyle=DOT,color=white):coeur2:=%:

 

>	display({H1_vec_field,H2_vec_field,coeur2},axes=framed,orientation=[45,65],projection=1,title="Champ magn?tique H dans la fibre\n? l'instant t=0. Mode TE[02]");

 

 

REPRESENTATION DU CHAMP MAGNETIQUE H DANS LE PLAN TRANSVERSAL DE LA FIBRE A L'INSTANT . 

>	display({H1_vec_field,H2_vec_field,coeur1},axes=boxed,orientation=[0,0],projection=1,title="Champ magn?tique H dans le plan transversal de la fibre\n? l'instant t=0. Mode TE[02]");

 

 

REPRESENTATION DU CHAMP MAGNETIQUE H DANS LE PLAN MERIDIEN DE LA FIBRE A L'INSTANT .  

>	fieldplot([Im(Hz1*exp(I*beta[z]*z)),Im(Hr1*exp(I*beta[z]*z))],z=0..lambda[g]/2,r=0..a,grid=[16,16],thickness=0,color=red,arrows=THICK,axes=BOXED):H1_mer_vec_field:=%:

 

>	fieldplot([Im(Hz2*exp(I*beta[z]*z)),Im(Hr2*exp(I*beta[z]*z))],z=0..lambda[g]/2,r=a..1.5*a,grid=[16,8],thickness=0,color=magenta,arrows=THICK,axes=BOXED):H2_mer_vec_field:=%:

 

>	display({H1_mer_vec_field,H2_mer_vec_field},title="Champ magn?tique H dans le plan m?ridien de la fibre\n? l'instant t=0. Mode TE[02]");

 

 

ANIMATION DE LA PROPAGATION DU CHAMP MAGNETIQUE H DANS LE PLAN MERIDIEN DE LA FIBRE 

>	animate( fieldplot, [[Im(Hz1*exp(I*(beta[z]*z-omega*t))),Im(Hr1*BesselJ(1,324804.2738*r)*exp(I*(beta[z]*z-omega*t)))],z=0..lambda[g]/2,r=0..a,thickness=0,color=red,arrows=THICK,axes=BOXED,title="Champ magn?tique H \ndans le plan m?ridien de la fibre. Mode TE[02]"], t=0..2*Pi/omega, frames=10 );

 

 

REPRESENTATION DE L'INTENSITE LUMINEUSE TRANSPORTEE DANS TOUTE LA FIBRE.  

>	f:=subs(r=sqrt(x^2+y^2),Im(Ephi1));

 

(11.25)

 

>	g:=subs(r=sqrt(x^2+y^2),Im(Ephi2));

 

(11.26)

 

>	fa:=piecewise( (x^2+y^2)>=a^2,g,(x^2+y^2)<=a^2,f);

 

(11.27)

 

>	densityplot(fa^2,x=-a..a,y=-a..a,grid=[100,100],style=patchnogrid,title="Intensit? lumineuse dans le plan transversal de la fibre.\n Mode TE[02]");

 

 

REPRESENTATION DE L'INTENSITE LUMINEUSE TRANSPORTEE DANS LA GAINE DE LA FIBRE.  

>	ga:=piecewise( (x^2+y^2)<=a^2,0,(x^2+y^2)>=a^2,g);

 

(11.28)

 

>	densityplot(ga^2,x=-1.5*a..1.5*a,y=-1.5*a..1.5*a,grid=[100,100],style=patchnogrid,title="Intensit? lumineuse dans la gaine de la fibre.\n Mode TE[02]");

 

 

CONCLUSION 

L'utilisateur de la pr?sente feuille d'application de Maple a la possibilit? d'effectuer les changements suivants : 

1) Garder la valeur de la fr?quence normalis?e et ?tudier le mode transverse ?lectrique correspondant au premier z?ro de l'?quation [30]. Cette ?tude consistera en : 

i) La d?termination des expressions du champ ?lectrique transversal dans le coeur et dans la gaine de la fibre. 

ii) La d?termination des expressions du champ magn?tique radial et longitudinal dans le coeur et dans la gaine de la fibre. 

iii) La repr?sentation dans l'espace ? trois dimensions des champs de vecteurs E et H.  

iv) La repr?sentation dans le plan transversal de la fibre de l'intensit? lumineuse associ?e au mode. 

2) L'utilisateur peut aussi ?tudier les modes transverses magn?tiques caract?ris?s par , et . 

3) Finalement, l'utilisateur peut changer la valeur de la fr?quence normalis?e, chercher les z?ros de l'?quation aux valeurs propres, d?signer un mode donn?, puis d?terminer les expressions des champs ?lectrique et magn?tique avant de les repr?senter graphiquement dans l'espace ? trois dimensions. 

REFERENCES 

[1] Feuille de Maple intitul?e : "Fibre Optique Multimode A Gradient D'Indice", disponible ? l'adresse ?lectronique : 

http://www.maplesoft.com/applications/app_center_view.aspx?AID=2022 

 

[2] John A. Buck, Fundamentals of Optical Fibers, John Wiley & Sons, Wiley-Interscience, New York, 1995. 

 

Legal Notice: The copyright for this application is owned by the author(s). Neither Maplesoft nor the author are responsible for any errors contained within and are not liable for any damages resulting from the use of this material. This application is intended for non-commercial, non-profit use only. Contact the author for permission if you wish to use this application in for-profit activities.